Подготовка ролика

Ролик содержит довольно мало элементов, за исключением клипа в библиотеке, представляющего блоки. Этот клип содержит 4 кадра, по кадру для каждого цвета. Также в каждом кадре есть маленькая картинка. Пятый кадр пустой и представляет пустое место в решетке. Первые четыре блока имеют кнопку, чтобы по ним можно было щелкнуть. Клипу необходимо присвоить имя в панели Linkage Properties, поскольку он не находится изначально на рабочем поле.

Главная временная шкала ролика включает в себя два кадра: первый, содержащий инструкции и кнопку Play, а второй – это кадр "Play".

Создание кода

Создание блоков происходит в функции startGame. Функция совершает циклы по 20 горизонтальным колонкам и 12 вертикальным рядам и создает 240 блоков. Каждый блок – это новый экземпляр клипа «block», созданного функцией attachMovie. Кроме того, чтобы оказаться в нужном месте рабочего поля, каждый блок обладает свойствами х и у, таким образом, позже он сможет определить свое положение.

Выбирается случайное число от 1 до 4, и клип с блоком отправляется к этому кадру.

function startGame() {

// Переходим к кадру игры.

gotoAndStop("Play");

score = 0;

// Создаем решетку из блоков.

level = 0;

for(var x=0;x<20;x++) {

for(var y=0;y<12;y++) {

mc = _root.attachMovie("block","block "+x+" "+y,level);

mc._x = 20*x + 85;

mc._y = 20*y + 60;

mc.x = x;

mc.y = y;

// Выбираем случайный цвет.

mc.gotoAndStop(Math.ceil(Math.random()*4));

level++;

}

}

}

Когда пользователь щелкает по блоку, чтобы выбрать его, короткий сценарий посылает свойства х и у блока функции, чтобы программа могла решить, какие действия предпринять.

on(release) {

_root.clickBlock(x,y);

}

Функция clickBlock определяет цвет блоков и хранит его в переменной с. Затем блок удаляется (точнее, его клип переходит к пустому кадру). Функция testNeighbor вызывается четыре раза, один раз для каждого соседа. Функция возвращает количество подходящих соседей, найденных в данном направлении. Если, например, сосед сверху того же цвета и три его соседа тоже, возвращается число 4. Добавляя это число к переменной n, вы получаете полное количество блоков в группе.

Если обнаружено, что группа состоит более чем из одного блока, вызываются функции collapseDown и collapseAcross, чтобы удалить все блоки группы. В противном случае выделенный блок возвращается к прежнему цвету, и кажется, что ничего не произошло.

// Произошел щелчок по блоку.

function clickBlock(x,y) {

Примечание

Обратите внимание на ключевое слово var перед описанием переменной c. Это делает c локальной переменной, существующей только в функции clickBlock. Любое использование c за пределами функции clickBlock будет отнесено к самостоятельной переменной. При применении рекурсивных техник, когда функция вызывает саму себя или похожую функцию, лучше использовать локальные переменные, чтобы переменные не наступали друг другу на пятки, когда программа движется от функции к функции.

// Определяем цвет этого блока.

var c = _root["block "+x+" "+y]._currentframe;

_root["block "+x+" "+y].gotoAndStop(5);

// Проверяем его соседей по всем направлениям.

var n = 1;

n += testNeighbor(x‑1,y,c);

n += testNeighbor(x+1,y,c);

n += testNeighbor(x,y‑1,c);

n += testNeighbor(x,y+1,c);

// Если один их них того же цвета.

if (n > 1) {

// Уничтожаем группу блоков.

collapseDown();

collapseAcross();

// Начисляем очки.

score += n*n;

} else {

// Оставляем блок на месте.

_root["block "+x+" "+y].gotoAndStop(c);

}

}

Функция testNeighbor проверяет цвет нового блока. Если цвет подходит, блок удаляется. Дальше функция вызывает сама себя и проверяет цвета четырех соседних блоков. Она следит за переменной n, которая определяет количество подходящих соседей.

Если текущий блок не подходит по цвету, вместо n возвращается 0, чтобы показать, что в этом направлении не было найдено ни одного подходящего блока.

function testNeighbor(x,y,c) {

if (_root["block "+x+" "+y]._currentframe == c) {

// Удаляем соседа.

_root["block "+x+" "+y].gotoAndStop(5);

var n = 1;

// Проверяем всех его соседей.

n += testNeighbor(x‑1,y,c);

n += testNeighbor(x+1,y,c);

n += testNeighbor(x,y‑1,c);

n += testNeighbor(x,y+1,c);

// Возвращаем количество найденных соседей.

return(n);

} else {

// Не найдено никаких подходящих блоков.

return(0);

}

}

После того как блок выбран и все соседи одного с ним цвета удалены, следующий шаг – это позволить всем оставшимся блокам упасть вниз на все свободные места. Это достигается прохождением по всем столбцам в цикле по переменной x. Затем, во вложенном цикле по y происходит проверка всех блоков в этом столбце снизу вверх. И если блок пустой, первый заполненный блок сверху смещается вниз.

function collapseDown() {

// Проходим по всем столбцам.

for(var x=0;x<20;x++) {

// Проходим по всем блокам столбца снизу вверх.

for(var y=11;y>0;y–) {

// Смотрим, пустой ли блок.

thisColor = _root["block "+x+" "+y]._currentFrame;

if (thisColor == 5) {

// Если да, просматриваем все блоки над ним.

for(var i=y‑1;i>=0;i–) {

// Если блок не пустой.

aboveColor = _root["block "+x+""+i]._currentframe;

if (aboveColor != 5) {

// Смещаем его вниз.

_root["block "+x+"

"+y].gotoAndStop(aboveColor);

_root["block "+x+" "+i].gotoAndStop(5);

break;

}

}

}

}

}

}

После того как все блоки передвинуты, может оказаться, что некоторые столбцы пустые. Если так произошло, весь столбец справа от пустого должен быть сдвинут влево, чтобы закрыть промежуток.

Чтобы это осуществить, функция collapseAcross движется сквозь все столбцы слева направо. Если найден пустой столбец, за которым следует непустой, то последний сдвигается влево на одну позицию.

Этот процесс повторятся снова и снова, пока не перестанут попадаться пустые столбцы. Тогда цикл оканчивается, и функция выполнена.

function collapseAcross() {

// Продолжаем, пока есть пустые столбцы.

do {

n = 0;

// Проверяем все столбцы.

for(var x=0;x<19;x++) {

// Если текущий столбец пустой.

if (_root["block "+x+" 11"]._currentframe == 5) {

// Если следующий – полный.

if (_root["block "+(x+1)+" 11"]._currentframe != 5)

{

n++;

// Смещаем все блоки.

for(var y=0;y<12;y++) {

c = _root["block "+(x+1)+" "+y]._currentframe;

_root["block "+x+" "+y].gotoAndStop(c);

_root["block "+(x+1)+" "+y].gotoAndStop(5);

}

}

}

}

// Цикл прекращается, если больше не обнаружено пустых

// столбцов.

} while (n > 0);

}