3.1.2. Проект «Снежинки»

Постановка задачи. Рисование снежинки на поверхности формы в точке, в которой пользователь нажал кнопку мыши. Демонстрирует использование процедуры PolyLine, а также процедуры обработки события OnMouseDown для получения координаты точки, в которой нажата кнопка мыши. При нажатии левой кнопки мыши цвет снежинки синий, а при нажатии правой – голубой (рис. 19).

Рис. 19. Результат работы программы «Снежинки»

Реализация. Напишем процедуру snowflake рисования снежинки. Входными параметрами для нее являются координаты x0, y0 центра снежинки и r − радиус снежинки.

procedure snowflake(x0,y0,r: integer);

// x0,y0 - координаты центра снежинки

// r - радиус снежинки

var p : array[1..21] of TPoint; // Массив координат лучей и впадин

a: integer; // Угол в градусах между осью Оx и прямой, // соединяющей центр снежинки и конец луча или впадины

i: integer;

begin

a := 18; // Строим от правого горизонтального луча

for i:=1 to 20 do

begin

if (i mod 2 = 0) then

begin // Впадина

p[i].x := x0+Round(r/6*cos(a*2*pi/360));

p[i].y:=y0-Round(r/6*sin(a*2*pi/360));

end

else

begin // Луч

p[i].x:=x0+Round(r*cos(a*2*pi/360));

p[i].y:=y0-Round(r*sin(a*2*pi/360));

end;

a := a+18;

end;

p[21].x := p[1].x; // Замкнуть контур снежинки

p[21].y := p[1].y;

Form1.Canvas.Polyline(p); // Начертить снежинку

end;

На событие OnMouseDown напишем код, в котором проверяем, какая кнопка была нажата.

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);

begin

if Button = mbLeft then // Нажата левая кнопка мыши

// Устанавливаем синий цвет

Form1.Canvas.Pen.Color := clBlue

else

// Задаём голубой цвет

Form1.Canvas.Pen.Color := clSkyBlue;

// Вызов процедуры отрисовки снежинки

snowflake(x, y, 10);

end;

3.1.3. Проект «Крестики-нолики»

Постановка задачи. Проект реализует известную игру «Крестики-нолики». Играющий ставит по очереди крестик или нолик в клетку поля, пока не наберет пять одинаковых элементов по горизотали, вертикали или диагонали. Вообще-то в эту игру играют двое, но мы делаем проект для одного игрока.

Реализация. Положите на форму компонент TPaintBox. Используйте процедуру DrawPole из параграфа «Рисование поля для различных игр» (пункт 2.1.2). Эта процедура рисует поле, состоящее из N х N квадратиков, как указано на рис. 20. Рисовать будем на компоненте TPaintBox, поэтому переменные x0 и y0 равны нулю и не будут использоваться. Клетки будут квадратные, значит, dx = dy (сторона квадратика в пикселях).

Зададим размер поля константой N = 5.

Н а рис. 20 выделен квадратик с номером строки i = 2 и номером столбца k = 3. Для нахождения координат этого квадратика на TPaintBox используем формулы (1):

x = (k –1) * dx;

y = (i– 1) * dy.

Обратно, зная x и y, можно найти номер строки и номер столбца по формулам (2):

Рис. 20. Поле для проекта

«Крестики-нолики»

k = x div dx+1;

i = y div dy+1.

Положите на форму одну надпись TLabel для вывода текста, напоминающего, чей следующий ход: крестиков или ноликов. Первыми обычно ходят крестики.

Опишите глобальную переменную булевского типа, означающую признак того, что ходят крестики, например:

var pr_krest:boolean.

Также необходимо описать двумерный массив с элементами целого типа. Массив нужен для того, чтобы узнать, кто победил: крестики или нолики. Процедурой mas_clear обнулите все элементы массива.

procedure mas_clear; {Обнуление элементов массива}

var i,k:integer;

begin

for i:=1 to N do

for k:=1 to N do

a[i,k]:=0;

end;

В процессе игры мышью будем указывать клетку, в которую надо выводить «Х» или «О» в зависимости от значения признака pr_krest. Эти буквы будем выводить с помощью метода TextOut. При этом мышь должна указать место на сетке, т. е. какой-либо квадратик с номером строки i и номером столбца k. Для нахождения значений переменных i и k будем использовать формулы (2).

В параметрах процедуры TForm1.PaintBox1MouseDown (Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer), являющейся обработчиком события «щелчок по левой кнопке», есть переменные x и y. Эти значения x и y подставим в формулы (2):

k := x div dx + 1;

i := y div dy + 1;

Так мы узнаем номер строки и номер столбца квадратика [i, k]. Кроме того, при щелчке мышью по клетке занесем в соответствующую ячейку массива a[i, k]:=1 (крестики) или a[i, k]:=2 (нолики). Надо не забыть, что ставить крестик или нолик мы можем только в том случае, если в соответствующей ячейке массива стоит 0. Ниже приведен код обработчика PaintBox1MouseDown.

procedure TForm1.PaintBox1MouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);

var c,b:integer;

begin

k:=x div dx +1;

i:=y div dy +1;

if a[i, k] = 0 then

begin

c:=(k-1)*dx+8; // Место для вывода символа

b:=(i-1)*dy+2;

with PaintBox1.Canvas do

begin

Font.Color:=clblue;

Font.Size:=18;

brush.color:=ClWhite;

end;

if pr_krest then

begin

PaintBox1.Canvas.TextOut(c,b,'X');

a[i,k]:=1;

{ Здесь должна быть проверка }

pr_krest:=false;

Label1.Caption:='Ход ноликов';

end

else

begin

PaintBox1.Canvas.TextOut(c,b,'О');

a[i,k]:=2;

{Здесь должна быть проверка}

pr_krest:=true;

Label1.Caption:='Ход крестиков';

end;

end;

end;

На рис. 21 показан момент игры «Крестики-нолики».

Рис. 21. Игра «Крестики-нолики»

После того как крестик или нолик поставлен, необходимо организовать проверку по горизонтали, вертикали и диагонали. В случае успеха вывести соответствующее сообщение, например, «Выиграли крестики!» В следующей функции line_vert организована проверка по вертикали.

function line_vert (i ,k, c : integer) : boolean;

{ Числа i, k – это номер строки и номер столбца квадратика [i, k], в который только что поставили крестик (переменная c равна 1) или нолик (переменная c равна 2) }

var p,q:integer;

begin

p:=i;q:=i; {Начинаем проверку от квадратика [i,k]}

while(p<=n)and(a[p,k]=c)do

{Идем вниз по полю}

p:=p+1;

while(q>=1)and(a[q,k]=c)do

{Идем вверх по полю}

q:=q-1;

if(p-q)=n+1 then

line_vert:=true else line_vert:=false;

end;

Игра заканчивается, если выигрыш или не осталось свободных клеток.

Задание. Организуйте проверку по горизонтали и диагоналям.