4. Моделирование силовой части
Рис.2. Имитационная модель
Текст программы:
*SPS course work mosfet models
.SUBCKT irf840 1 2 3
**************************************
* Model Generated by MODPEX *
*Copyright(c) Symmetry Design Systems*
* All Rights Reserved *
* UNPUBLISHED LICENSED SOFTWARE *
* Contains Proprietary Information *
* Which is The Property of *
* SYMMETRY OR ITS LICENSORS *
*Commercial Use or Resale Restricted *
* by Symmetry License Agreement *
**************************************
* Model generated on Apr 2, 99
* MODEL FORMAT: SPICE3
* Symmetry POWER MOS Model (Version 1.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
M1 9 7 8 8 MM L=100u W=100u
* Default values used in MM:
* The voltage-dependent capacitances are
* not included. Other default values are:
* RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=3.99 LAMBDA=0.000144225 KP=2.88036
+CGSO=6.42864e-06 CGDO=1e-11
RS 8 3 0.0001
D1 3 1 MD
.MODEL MD D IS=7.93539e-09 RS=0.020221 N=1.5 BV=400
+IBV=0.00025 EG=1.2 XTI=3.05954 TT=0
+CJO=5.57785e-10 VJ=5 M=0.688789 FC=0.5
RDS 3 1 1e+06
RD 9 1 0.485778
RG 2 7 2.63633
D2 4 5 MD1
* Default values used in MD1:
* RS=0 EG=1.11 XTI=3.0 TT=0
* BV=infinite IBV=1mA
.MODEL MD1 D IS=1e-32 N=50
+CJO=8.85779e-10 VJ=2.49436 M=0.9 FC=1e-08
D3 0 5 MD2
* Default values used in MD2:
* EG=1.11 XTI=3.0 TT=0 CJO=0
* BV=infinite IBV=1mA
.MODEL MD2 D IS=1e-10 N=0.510385 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 8.85779e-10
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
* Default values used in MD3:
* EG=1.11 XTI=3.0 TT=0 CJO=0
* RS=0 BV=infinite IBV=1mA
.MODEL MD3 D IS=1e-10 N=0.510385
.ENDS irf840
**************************************
* Model Generated by MODPEX *
*Copyright(c) Symmetry Design Systems*
* All Rights Reserved *
* UNPUBLISHED LICENSED SOFTWARE *
* Contains Proprietary Information *
* Which is The Property of *
* SYMMETRY OR ITS LICENSORS *
*Commercial Use or Resale Restricted *
* by Symmetry License Agreement *
**************************************
* Model generated on Feb 4, 02
* MODEL FORMAT: SPICE3
.MODEL 10ctq150 d
+IS=1.63362e-06 RS=0.0221615 N=2 EG=0.6
+XTI=0.5 BV=150 IBV=5e-05 CJO=4.60092e-10
+VJ=0.759589 M=0.500823 FC=0.5 TT=1e-09
+KF=0 AF=1
************************************
.param Vs_min=380V
.param Vs_max=420V
.param T=2.5us
.param Ldop=1e-12H
.param gamma=0.75
*.param gamma=0.9
.param n=0.298
.param Rgate=5
.param ILFIC=20;
.param UCIC=48;
.param IW1IC=0;-50.012u
.param UC7IC={Vs_min/2}
.param UC8IC={Vs_min/2}
*.param Rn=4.8
.param Rn=48
V1 1 0 {Vs_min}
*V1 1 0 {Vs_min}
ViX1 1 30 dc 0
******************************
x1 30 5 2 irf840
x2 2 6 0 irf840
******************************
C10 1 3 3.3uF IC={UC7IC};{Vs/2}
C11 3 0 3.3uF IC={UC8IC};{Vs/2}
R15 1 3 43k
R16 3 0 43k
*******************************
L13 2 12 1m
F23 2 12 Vi23 0.2675
F33 2 12 Vi33 0.2675
********************************* W23
Ris3 19 0 10000k
E23 10 19 2 12 0.2675
Vi23 10 21 dc 0
R8 21 22 0.001
D9 22 9 10ctq150
********************************* W33
E33 19 24 2 12 0.2675
Vi33 25 24 dc 0
R9 25 26 0.001
D10 26 9 10ctq150
*********************************
Vdt 12 3 dc 0
D11 19 9 10ctq150
Lf 9 131 3.3uH IC={ILFIC}
Rl 131 13 10u
C12 13 19 22uF IC={UCIC}
R 13 19 {Rn}
C1112 13 19 2PF IC={UCIC}
C123112 13 19 10PF IC={UCIC}
************************************
Vg1 51 2 pulse(0 12 0 5n 5n {0.89*T} {2*T})
Vg2 61 0 pulse(0 12 {T} 5n 5n {0.89*T} {2*T})
Rg1 51 5 {Rgate}
Rg2 61 6 {Rgate}
.Option Gmin=1n ITL4=200 ABSTOL=10n
.tran 50n 1500u 50n 50n UIC
.probe
.end
Моделирование схемы проведём с реальными элементами. В качестве транзисторов выберем транзисторы IRF820. В качестве диодов возьмём модель 10CTQ150.
Рис.
3. Напряжение на нагрузке при максимальной
мощности и минимальном напряжении
питания.
Напряжение на выходе, а точнее на выходном конденсаторе меняется в зависимости от проводящего состояния силового ключа VT2. Когда ключ находится в проводящем состоянии: происходит передача энергии в нагрузку, через индуктивность L1 течет ток, выходная емкость С12 заряжается. Когда же ключ VT2 не проводит, энергия в нагрузку не передается, С12-разряжается.
Рис.4. Ток через диод D9
Ток через диод D9 идет когда в проводящем состоянии находится ключ VT2,
и спадает до 0 когда ключ VT2 перестает проводить и энергия от источника не передается в нагрузку.
Рис.5 Ток через диод D11
Ток через диод VD11 идет всякий раз, когда закрыты диоды VD9, VD10 и ток индуктивности L1 замыкается через - выходную емкость C12 в параллель с Rn, диод VD11, индуктивность L1.
Рис.6
Потери в транзисторе.
Потери в транзисторе обусловлены потерями в проводящем состоянии и потерями при коммутации.
Как видно из рисунка 6, Pstatic=3.7Вт, Pon=0.421Вт, Poff=0.512 Вт, Psum=4.633 Вт. При максимальной мощности отдаваемой в нагрузку 480Вт.
Рис.
7 Потери в диоде VD9.
Pпот_VD9=4.936 Вт
Потери в диоде обусловлены потерями в проводящем состоянии и потерями при коммутации.
Рис.8.
Потери в диоде VD11.
Pпот_VD11=0.130 Вт
Потери в диоде обусловлены потерями в проводящем состоянии и потерями при коммутации.
Коэффициент полезного действия будет равен:
Рис.9. Ток дросселя при минимальной мощности, отдаваемой в нагрузку и максимальном напряжении питания.
Ток дросселя: во время первого такта, когда диоды VD9, VD10 открыты и транзистор VT2 находится в проводящем состоянии, к дросселю L1 приложено напряжение , ток в индуктивности линейно нарастает. Когда же диоды VD9, VD10 закрыты, а диод VD11 открыт- ток в дросселе линейно спадает так как к нему приложено напряжение .
Рис.10. Напряжение на нагрузке при минимальной мощности, отдаваемой в нагрузку и максимальном напряжении питания.
Здесь процессы аналогичны процессам описанным выше для напряжения на нагрузке при максимальной мощности и минимальном напряжении питания (рис.1), только в этом случае среднее значение выходного напряжения меньше..
Рис. 11. Напряжение на транзисторе VT3.