15. Закрытие и удаление файла

Функция DOS 3Eh — Закрыть файл

Ввод: АН = 3Eh

ВХ = идентификатор

Вывод: CF = 0, если не произошла ошибка

CF = 1 и АХ = 6, если неправильный идентификатор

Если файл был открыт для записи, все файловые буфера сбрасыва­ются на диск, устанавливается время модификации файла и записывается его новая длина.

Функция DOS 41h — Удаление файла

Ввод: АН = 41h

DS:DX = адрес ASCIZ-строки с полным именем файла

Вывод: CF = 0, если файл удален

CF = 1 и АН = 02h, если файл не найден, 03h, если путь не най­ден, 05h, если доступ запрещен.

Удалять файл следует только после того, как он будет закрыт, иначе DOS будет продолжать выполнять запись в несуществующий файл, что может привести к разрушению файловой системы. Функция 41h не позволяет использовать маски (символы «*» и «?» в имени файла) для удаления сразу нескольких файлов, хотя этого можно добиться, вызы­вая ее через недокументированную функцию 5D00h. Официальная функция удаления файла, позволяющая удаление сразу нескольких файлов, появилась в системе DOS 7.0 (Windows 95):

Функция LFN 41h — Удаление файлов с длинными именами

Ввод: AX = 7141h

DS:DX = адрес ASCIZ-строки с длинным именем файла

SI = 0000h: маски не разрешены и атрибуты в СХ игнорируются

SI = 000lh: маски в имени файла и атрибуты в СХ разрешены:

CL = атрибуты, которые файлы могут иметь

СН = атрибуты, которые файлы должны иметь

Вывод: CF = 0, если файл или файлы удалены

CF = 1 и АХ = код ошибки, если произошла ошибка. Код 7100h означает, что функция не поддерживается.

Ниже приведен пример простой программы, иллюстрирующей использование файловых функций. Осуществляются создание файла в текущем каталоге, запись в него текстовой строки и закрытие файла. (В простых программах, подобных этой, явное закрытие файла можно не производить, так функция 4Ch автоматически закрывает все открытые файлы перед возвратом управления операционной системе).

dat segment

fname db '1.txt', 0 ; ASCIIZ-имя файла

string db 'Данные' ; записываемая строка

len = $-string ; длина строки

ermes db 'Ошибка создания файла!'

erLen = $-ermes ; длина сообщения об ошибке

dat ends

cod segment

assume cs:cod,ds:dat

b: mov ax, dat

mov ds, ax ; инициализация DS адресом сегмента данных

;Создадим файл

mov ah, 3Ch ; функция ’Создать файл’

lea dx, fname ; DS:DX -> ASCIIZ-имя

xor cx,cx ; без атрибутов

int 21h

jc er ; если ошибка – на обработку

;Запишем в файл строку

mov bx, ax ; сохраним дескриптор созданного файла

mov ah, 40h ; функция записи в файл или на устройство

lea dx, string ; DS:DX -> записываемая строка

mov cx, len

int 21h

;Закроем файл (в BX - дескриптор)

mov ah, 3Eh

int 21h

exit: mov ax, 4c00h

int 21h

;Обработка ошибки создания файла – вывод сообщения

er: mov ah, 40h ; функция записи в файл или на устройство

mov bx, 1 ; дескриптор, соответствующий экрану

lea dx, ermes ; DS:DX -> сообщение об ошибке

mov cx, erLen ; его длина в байтах

int 21h

jmp exit

cod ends

end b