48. Пример отображения на форме vb графика функции с использованием объектной модели ms Excel. Рассмотреть способ передачи графика через диск и через буфер обмена.

Пример. (Отобразить на форме график функции, используя объектную модель MS Excel.)

Private Sub Command1_Click()

Dim GraphFunc As String, FileName As String, ObjRange As Object

Dim xmin As Double, xmax As Double, h As Double, ObjExcel As Object

'xmin - начало диапазона, xmax - конец, h -шаг

Dim n As Integer ' счетчик строк

Const xlLines = 4

Const xlColumns = 2

Const xlPrimary = 1

Const xlCategory = 1

Const xlLocationasObject = 2

'Создаем объект OLE Automation

Set ObjExcel = CreateObject("Excel.Application")

'Задаем свойства рабочей книги и листа

With ObjExcel

.WorkBooks.Add

.ActiveSheet.Name = "График"

.Visible = True

.DisplayAlerts = False

End With

ObjExcel.Range("A1:B150").Clear

' Присваиваем имя "X" ячейки A1

ObjExcel.Range("A1").Name = "X"

'Считываем параметры графика из полей

GraphFunc = "=" & Text1

xmin = Text2

xmax = Text3

h = Text4

'Задаем параметры графика и координатной сетки

With ObjExcel.WorkSheets("График")

.Range("A1").Value = xmin

.Range("A1").DataSeries RowCol:=xlColumns, Step:=h, Stop:=xmax

'Определяем число заполненных строк

n = .Range("A2").CurrentRegion.Rows.Count

.Range("B1").Formula = GraphFunc

.Range("A1:A" & LTrim(CStr(n))).Name = "X"

.Range("B1").AutoFill Destination:=.Range(.Cells(1, 2), .Cells(n, 2)), Type:=0

End With

FileName = App.Path& "\График.gif" ' App.Path – путь к файлу

With ObjExcel

.Charts.Add

.ActiveChart.ChartArea.Font.Size = 10

.ActiveChart.ChartArea.Font.Bold = True

.ActiveChart.ChartArea.Font.Name = "Times New Roman Cyr"

.ActiveChart.ChartType = xlLines

.ActiveChart.ChartArea.Interior.ColorIndex = 6 'Желтый

.ActiveChart.ChartArea.Border.ColorIndex = 5 'Синий

.ActiveChart.PlotArea.Interior.ColorIndex = 2 'Белый

.ActiveChart.SetSourceData Source:=.Sheets("График").Range("B1:B" & LTrim(CStr(n))), PlotBy:=xlColumns

.ActiveChart.SeriesCollection(1).XValues = "=График!R2C1:R" & LTrim(CStr(n) & "C1")

.ActiveChart.Location Where:=xlLocationasObject, Name:="График"

With .ActiveChart

.HasTitle = True

.ChartTitle.Characters.Text = Trim(Text1)

.Axes(xlCategory, xlPrimary).HasTitle = True

.Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "X"

.HasLegend = False

.Export FileName, FilterName:="GIF"

End With

Image1.Picture = LoadPicture(FileName) 'Загружаем график с диска

End With

ObjExcel.Quit 'Закрываем Excel без сохранения

Set ObjExcel = Nothing ' Удаление объекта

End Sub

Private Sub Form_Load()

Caption = "Пример на OLE Automation"

Command1.Caption = "График"

Text1 = "3 * SIN(ABS(X)^0.5) + 0.35 * X - 3.8"

Text2 = "-1"

Text3 = "8"

Text4 = "0,1"

Text1.TabIndex = 0

End Sub

Когда запись на диск из прикладной программы невозможна (например, проект был запущен с компакт-диска), то диаграмму следует передавать на форму через буфер обмена. Тогда вместо следующих строк

FileName= App.Path& "\Градус.gif"

ObjExcel.ActiveChart.ExportFileName, filtername:="GIF"

Image1.Picture = LoadPicture(FileName)

Следует записать строки:

ObjExcel.ActiveChart.ChartArea.Select

'Если диаграмма была уже выделена, то не нужно методом Select дополнительно ее выделять

ObjExcel.ActiveChart.ChartArea.Copy

Image1.Picture = Clipboard.GetData