6.2. Расчет переходных характеристик
При расчете вводим цепь коррекции (R21, C13), задаем импульс входного напряжения, импульс выходного тока и смотрим реакцию выходного напряжения. Подбирая параметры цепи коррекции, добиваемся нужного результата.
Текст программы для расчета переходных характеристик:
*
* serj
.param Rn=2.7
.param N=0.7
.param f=100k
.param T={1/f}
.param L=820u
.param K1=0.39
.param K2=0.27
.param Vv=0.4
.param Vp=2.2
*Vs 1 0 350
Vsp 1 0 pulse(175 350 0.1m 1u 1u 2m 4m)
Vsac 2 1 0
Rsac 2 0 1k
Eb 3 0 value={V(2)*V(d)*N/2}
Reb 3 4 0.02
L 4 13 {L}
Vil 13 5 0
Rc 5 12 0.000714
C 12 0 5.1u
Rn 5 0 {Rn}
*Iac 5 0 0
Isp 5 0 pulse (0 1 2m 1u 1u 2m 4m)
**********correction circuit
C13 7 6 10n
R21 6 5 1k
**********
R19 5 7 20.5k
R20 0 7 1000
R22 15 0 100k
R23 5 15 1000
Rd 15 8 40
Vfd 8 9 1
G1 9 0 value={ABS(3*(V(7)-2.5))}
G2 a 0 Value={I(Vfd)*1}
R6 a 0 10k
R5 10 a 330
Vr2 10 0 5
Rdac d 0 10k
Vdac d 11 ac 1
Ed 11 0 value={(V(a)-K1*I(ViL)-Vv*K2)/((V(2)*N-V(5))*K1*T/(4*L)+Vp*K2)}
*.dc Vs 250 300 10
.tran/op 0.1u 4m 0 0.1u
*.ac dec 10 1 1MEG
.OPTION ITL4=200 Gmin=1e-9 ABSTOL=1e-6 VNTOL=1e-3
.probe
.end
Рис. 16. Реакция на скачки напряжения и тока.
6.3. Расчет частотных характеристик
Текст программы:
*
* serj
.param Rn=2.7
.param N=0.7
.param f=100k
.param T={1/f}
.param L=820u
.param K1=0.39
.param K2=0.27
.param Vv=0.4
.param Vp=2.2
*.STEP param Rn 4 30 12
Vs 1 0 350
*Vsp 1 0 pulse(175 350 0.1m 1u 1u 2m 4m)
Vsac 2 1 0
Rsac 2 0 1k
Eb 3 0 value={V(2)*V(d)*N/2}
Reb 3 4 0.02
L 4 13 {L}
Vil 13 5 0
Rc 5 12 0.000714
C 12 0 5.1u
Rn 5 0 {Rn}
Iac 5 0 0
*Isp 5 0 pulse (0 1 2m 1u 1u 2m 4m)
**********correction circuit
C13 7 6 10n
R21 6 5 10k
**********
R19 5 7 20.5k
R20 0 7 1000
R22 15 0 100k
R23 5 15 1000
Rd 15 8 40
Vfd 8 9 1
G1 9 0 value={ABS(3*(V(7)-2.5))}
G2 a 0 Value={I(Vfd)*1}
R6 a 0 10k
R5 10 a 330
Vr2 10 0 5
Rdac d 0 10k
Vdac d 11 ac 1
Ed 11 0 value={(V(a)-K1*I(ViL)-Vv*K2)/((V(2)*N-V(5))*K1*T/(4*L)+Vp*K2)}
*.dc Vs 250 300 10
*.tran/op 0.1u 4m 0 0.1u
.ac dec 10 1 100k
.OPTION ITL4=200 Gmin=1e-9 ABSTOL=1e-6 VNTOL=1e-3
.probe
.end
Рис.17. Коэффициент передачи по напряжению
Рис.18. Вид алитудо- и фазо- частотных характеристик.