Чтение файлов последовательного доступа

Для чтения данных из файлов последовательного доступа используются операторы:

1. Input# ѕ данные в файле записаны оператором Write#

2. LineInput# ѕ данные в файле записаны оператором Print#.

Оператор Input# вызывается так:

Input #номер-файла, список-переменных

• Параметр номер-файла - номер открытого файла,

• список-переменных - одно или несколько разделенных запятыми имен переменных, в которые будут считываться данные из файла. Переменные могут быть разных типов, естественное требование их тип должен быть согласован с типом записи в момент ее создания. Переменные не должны быть массивами или объектами, но могут быть элементами массивов или полями пользовательских записей.

При чтении автоматически выполняются преобразования данных, обратные тем, что использовались при записи оператором Write#. В частности, кавычки вокруг строк, разделяющие запятые и пустые строки, игнорируются. Слово #NULL# дает значение Null, #TRUE# и #FALSE# переводятся в булевы значения True и False, универсальные даты вида #yyyy-mm-dd hh:mm:ss# переводятся в формат соответствующих переменных типа дата/время, #ERROR номер-ошибки# при чтении передает в переменную типа Variant номер ошибки. Если для числовой переменной соответствующие по порядку в файле данные будут не числовыми, ей будет присвоено значение 0.

По достижении конца файла, следующая попытка чтения из него приведет к ошибке. Во избежание этого для проверки на конец файла используется функцию:

EOF(номер-файла)

Она возвращает булево значение True, когда при чтении достигается конец файла, открытого в режиме последовательного доступа Input или произвольного доступа Random.

Приведем процедуру чтения записей ранее созданного файла "readme.txt". Заметьте, мы поступаем корректно, читаемые переменные имеют тип, согласованный с типом читаемой записи.

Public Sub ReadingWithInput()

Dim MyStr As String, MyBool As Boolean, MyDate As Date

Dim MyNull As Variant, MyFloat As Double, MyErr As Variant

Dim i As Integer

'Открытие файла readme.txt

Open Path & "readme.txt" For Input As #7

'Чтение файла

'Первые 8 строк

For i = 1 To 8

Input #7, MyStr

Debug.Print MyStr

Next i

'Данные разных типов

Input #7, MyBool, MyDate, MyNull, MyFloat

Debug.Print MyBool, MyDate, MyNull, MyFloat

'читаем отформатированные числа

Input #7, MyStr

Debug.Print MyStr

Input #7, MyStr

Debug.Print MyStr

'дважды читаем данные типа Error

Input #7, MyErr

Debug.Print MyErr

Input #7, MyErr

Debug.Print MyErr

'чтение до конца файла

Do While Not EOF(7)

Input #7, MyStr

Debug.Print MyStr

Loop

End Sub

Пример 14.4. (html, txt)

В результате будет напечатано:

Первая строка файла

Зона 1

Зона 2

Привет,

старик!

Мама

мыла

раму мылом.

False 14.06.99 Null 3,1416

3,14

03,142

6

Error 2000

Обратите внимание, процедура завершается циклом, типичным при чтении последовательных файлов. В данном случае он не работал ни разу, поскольку все записи файла уже были прочитаны к началу выполнения цикла.

Для построчного ввода данных из файлов с последовательным доступом, созданных оператором Print, вызывается оператор Line Input#:

Line Input #номер-файла, переменная

Здесь номер-файла имеет тот же смысл, что и для оператора Input, а переменная - имя строковой переменной или переменной типа Variant, в которую будет прочитана очередная строка файла. Оператор Line Input# считывает данные посимвольно, пока не обнаружит признак конца строки - символ возврата каретки (Chr(13)) или пару "возврат каретки - перевод строки" (Chr(13) + Chr(10)). Эти признаки в переменную не записываются. Никаких преобразований данных при построчном вводе не производится. Мы уже приводили пример чтения файла "read.me", созданного оператором Print#.

Следует заметить, что любой файл может быть открыт для чтения и прочитан оператором Line Input#. Другое дело, что, чаще всего, это не даст желаемого результата. Если, например, прочитать файл "readme.txt" с использованием оператора Line Input#, то будут получены следующие результаты:

"Первая строка файла"

"Зона 1","Зона 2"

"Привет,","старик!"

"Мама ","мыла ","раму мылом. "

#FALSE#

#1999-06-14#

#NULL#

3.1416,"3,14","03,142"

6

#ERROR 2000#

Несмотря на успех чтения, результаты не приемлемы, поскольку не выполняется нужного редактирования. Сохраняются кавычки, запятые, ограничители, в одной строке содержатся данные разных типов. Поэтому оператор Line Input # следует применять, как правило, для чтения строк из файлов, записанных с помощью оператора Print#.

Оператор Line Input # позволяет читать файл строка за строкой. Наряду с этим в языке VBA есть возможность чтения из файла произвольного числа символов или произвольного числа байтов. Для чтения символов Input или Binary файлов используется функция Input, имеющая следующий синтаксис:

Input(размер, [#]номер-файла)

где размер - количество считываемых символов, номер-файла - номер открытого файла (последовательного или бинарного). Данные, считываемые этой функцией, обычно должны быть записаны в файл операторами Print# или Put.

Еще один вариант этой функции:

InputB(размер, [#]номер-файла)

позволяет считывать из файла заданное количество байтов (не обязательно соответствующих символам). Заметьте, эта функция читает все символы, хранимые в файле, в том числе запятые, ограничители, символы конца строки и другие.