23. Модули. Создание модулей

Применение готовых и разработанных программистом модулей позволяет эффективно решать задачу повторного использования однажды написанного кода.

23.1. Назначение и структура модулей

Модулями называют заранее скомпилированные библиотеки подпрограмм, которые программист может использовать для создания новых программ. При программировании на Паскале модули подключаются из специальных библиотечных файлов, имеющих тип *.tpu (Turbo Pascal Unit). Модуль сам по себе не является выполняемой программой, но его подпрограммы используются другими программами.

Для того, чтобы создать модуль, нужно написать файл с расширением *.pas, соблюдающий описанную далее структуру модуля, затем в меню Compile оболочки Паскаля установить переключатель Destination в значение Disk (как мы помним, это же нужно сделать, если Вы собираетесь получить из своей программы на Паскале приложение *.exe), затем собрать модуль, выбрав в меню Compile пункт Build. После устранения ошибок компиляции готовый модуль (файл с расширением *.tpu) будет находиться в папке Паскаля.

Структура модуля такова (новые ключевые слова выделены жирным):

unit Имя; {Это заголовок модуля, именующий его. По этому имени модуль может быть подключен из программы оператором uses}

interface {Интерфейсная часть - здесь мы объявляем

константы, типы данных, переменные, процедуры и функции.

Тела общих процедур и функций находятся в разделе реализации.

Раздел интерфейса является общим. В нем можно определить то, что будет

видимо и доступно для любой другой программы (или модуля),

использующей данный модуль. В интерфейсной части может находиться раздел

Uses, если модуль подключает другие модули. В таком случае, слово Uses должно

следовать сразу за словом Interface}

implementation

{В разделе реализации (Implementation) модуля находятся тела процедур и функций,

объявленных в интерфейсной части.

Раздел реализации является частным. Все объявления, сделанные здесь могут быть

видимы только внутри данного раздела модуля.

Все константы, типы, переменные, процедуры и функции, объявленные в

интерфейсной части видимы в разделе реализации.

В разделе реализации могут находиться ее собственные дополнительные объявления,

невидимые любым программам, использующим модуль.

Раздел Uses может находиться в части реализации сразу после

зарезервированного слова Implementation.

Заголовок процедуры/функции в разделе реализации должен быть идентичен

объявлению в разделе интерфейса}

begin

{обычно "главная программа" модуля пуста. Здесь можно давать начальные

значения данным модуля, открывать используемые им файлы, если таковые есть,

и т.п.}

end.

Для работы с координатами точек на плоскости создадим простейший модуль и вызовем его подпрограммы его при написании новой программы:

unit Points;

interface

type point = array [1..2] of real;

procedure put (var p:point;x,y:real);

function distance (p1,p2:point):real;

function corner (p1:point):integer;

implementation

procedure put (var p:point;x,y:real);

begin

p[1]:=x; p[2]:=y;

end;

function distance (p1,p2:point):real;

begin

distance:=sqrt(sqr(p1[1]-p2[1])+sqr(p1[2]-p2[2]));

end;

function corner (p1:point):integer;

begin

if p1[1]>0 then begin

if p1[2]>0 then corner:=1

else if p1[2]<0 then corner:=4

else corner:=0;

end

else if p1[1]<0 then begin

if p1[2]>0 then corner:=2

else if p1[2]<0 then corner:=3

else corner:=0;

end

else corner:=0;

end;

begin

end.

Наш модуль определяет тип данных Point (точка) как массив из 2 вещественных чисел. Процедура put позволяет задать для точки значения x- и y-координаты, функция distance возвращает расстояние между двумя точками, а функция corner – номер координатной четверти, в которой находится точка, или 0, если точка лежит на одной из осей координат. Разумеется, реальные модули могут включать сотни функций, если предметная область, которую они моделируют, достаточно сложна. Теперь напишем маленькую тестовую программу, использующую наш модуль:

uses Points;

var a,b:Point;

begin

put (a,1,1);

put(b,0,0);

writeln ('Расстояние от A до B=',distance(a,b):8:3);

writeln ('Номер координатной четверти для A=',corner(a));

end.

Оператор uses, подключающий модуль, указан в первой строке программы. Во время компиляции этой программы в текущем каталоге должен присутствовать файл points.tpu, содержащий созданный ранее модуль Points.

При сборке сложной программы Паскаль ищет модули только в тех папках, которые перечислены в поле ввода Unit directories окна Directories верхнего меню Options, поэтому все готовые модули следует либо помещать в одну из этих папок, либо дописать в поле ввода нужные пути к папкам. В Приложении 4 приводится полный листинг модуля для работы с "мышью" из программы на Паскале и тесты для него.