Глава 1.Разные звери в одном ковчеге

В предыдущей главе я рассматривал массивы - структуры, состоящие из многих данных и объектов. В этой главе я продолжу рассматривать сложные структуры данных и объектов. Но если массивы - это одинаковые солдатики, стоящие стройными рядами в своих строгих батальонах, то те структуры, что мы рассмотрим в этой главе, больше напоминают натюрморт.

1.1.Тип Variant

Массив - это набор элементов. Если вы объявили массив некоторого типа, то он обязан состоять из элементов только этого типа. Например, каждый из десяти элементов массива, объявленного как

Dim a(1 To 10) As Integer

обязан быть целым числом. Ни один из них не имеет права быть строкой или дробным числом.

Имеется целый ряд задач, где хотелось бы, чтобы элементы в наборе имели разный тип. Этого можно достичь, если вообще не объявлять тип массива:

Dim a(1 To 3)

Private Sub Command1_Click()

a(1) = 32

a(2) = "кошка"

a(3) = #8:56:00 AM#

End Sub

В этом случае Visual Basic считает, что массив объявлен по умолчанию специальным типом Variant. Это тип-хамелеон. Он не возражает, если объявленная им переменная будет иметь значение любого типа. Он присматривает, чтобы выполнение программы при этом проходило по возможности гладко и без неприятностей для программиста.

Вместо Dim a(1 To 3) можно было прямо написать Dim a(1 To 3) As Variant.

Еще один пример всеядности Variant (здесь я объявлю этим типом не массив, а переменную):

Dim b As Variant 'можно было просто написать Dim b

Private Sub Command1_Click()

b = 77

b = "кот"

End Sub

Итак, если переменная не объявлена или объявлена без указания типа, Visual Basic считает ее принадлежащей типу Variant. Какой толк от этого типа? Иногда бывает так, что соблюдая приличия и объявляя тип каждой переменной, мы наталкиваемся во время выполнения программы на сообщение об ошибке Type mismatch (несовпадение типов). Это значит, что выполняя операции над данными разных типов и преобразовывая один в другой, Visual Basic не захотел преступать строгие рамки безопасности и приличий и потерпел крах. Не всегда у начинающего программиста хватает знаний, чтобы разобраться в причинах краха. В этом случае, если вы любите риск, объявите все данные одним типом - Variant или вообще не указывайте тип. Теперь вероятность сообщений об ошибке снизится, хотя несколько увеличится вероятность получения недостоверного результата.

Вернемся к нашему желанию иметь набор из элементов разных типов. Программисты не хотят для этого использовать массивы типа Variant. Они используют для этого так называемый пользовательский тип данных.

1.2.Пользовательский тип данных

В Паскале пользовательскому типу данных соответствуют записи, в языке Си - структуры. Рассмотрим простейший пример пользовательского типа:

Вы хотите занести в компьютер информацию о ваших любимых компьютерных играх, чтобы затем как-то ее анализировать, например, определить, какая игра занимает самое большое место на диске. Для простоты ограничим информацию об игре тремя элементами:

• Название игры

• Сколько места игра занимает на диске (в мегабайтах)

• Хорошая или плохая графика у игры (ваша оценка)

Также для экономии места ограничимся двумя играми. Ваша программа должна будет занести в память информацию об обеих играх, а затем выполнить три задания:

• Распечатать название первой игры

• Определить, сколько места займут на диске обе игры вместе

• Ответить, хороша или плоха графика у второй игры

Ваши действия: Для начала нужно создать пользовательский тип данных для размещения информации об одной игре. Нам уже приходилось конструировать перечислимый тип (см.7.3). Здесь действуем аналогично - придумываем новому типу имя (типИгра) и пишем:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

End Type

Тип определен. (Объяснение слова Private отложим на будущее). Теперь Visual Basic знает, сколько места в памяти занимает информация об игре и какая у нее структура. Можно отводить место в памяти:

Dim Игра1 As типИгра

Dim Игра2 As типИгра

Вот полный текст программы:

'Создаем пользовательский тип:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

End Type

'Отводим в памяти место под информацию о двух играх:

Dim Игра1 As типИгра

Dim Игра2 As типИгра

____________________________________________________________________

Private Sub Form_Load()

'Заносим в память компьютера информацию об играх:

Игра1.Название = "StarC": Игра2.Название = "Heroes III"

Игра1.Объем = 90: Игра2.Объем = 200

Игра1.Графика_хорошая = False: Игра2.Графика_хорошая = True

'Выполняем 1 задание:

Debug.Print Игра1.Название

'Выполняем 2 задание:

Debug.Print Игра1.Объем + Игра2.Объем

'Выполняем 3 задание:

If Игра2.Графика_хорошая Then Debug.Print "Хорошая графика" Else Debug.Print "Плохая графика"

End Sub

Обратите внимание, что имя элемента отделяется от имени переменной точкой подобно тому, как название свойства объекта отделяется точкой от имени объекта.

Выстроенную подобным образом в памяти информацию о чем-либо часто называют базой данных. Всю информацию об одной переменной (в нашем случае об одной игре) называют записью в этой базе данных. Программу, которая извлекает информацию из базы данных, сортирует записи и производит другую обработку информации в базе данных, называют системой управления базой данных. В нашем примере роль системы управления базой данных играет процедура Form_Load.

Элементы пользовательского типа могут иметь любой известный вам тип, в том числе быть массивом или пользовательским типом. Пусть вы хотите дополнить информацию об игре именами персонажей игры (не более 20). Вот каким массивом дополнится определение типа:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

Персонаж(1 To 20) As String

End Type

Теперь можно использовать такие операторы:

Игра2.Персонаж(4) = "Криган"

Игра1.Персонаж(12) = "Fenix"

Debug.Print Игра1.Персонаж(10)

Усложним задание: Вы хотите создать базу данных о 30 играх. Для этого достаточно вместо объявлений

Dim Игра1 As типИгра

Dim Игра2 As типИгра

объявить массив:

Dim Игра(1 To 30) As типИгра

Теперь можно использовать операторы:

Игра(16).Название = "StarCraft" 'название 16-й игры

Игра(8).Персонаж(12) = "Солдат" 'двенадцатый персонаж восьмой игры

Debug.Print Игра(16).Название, Игра(8).Персонаж(12)

Еще усложним задание: Вы хотите задать более подробную информацию о персонажах, а не только их имя. Вас интересует имя персонажа, количество его здоровья (в численном виде), название его оружия. Для этого вы определяете еще один пользовательский тип. Вот программа:

'Сначала создаем пользовательский тип персонажа,

'так как без него нельзя определить пользовательский тип игры:

Private Type типПерсонаж

Имя As String

Здоровье As Integer

Оружие As String

End Type

'Затем создаем пользовательский тип игры:

Private Type типИгра

Название As String

Объем As Integer

Графика_хорошая As Boolean

Персонаж(1 To 20) As типПерсонаж 'Не больше 20 персонажей в одной игре

End Type

'Отводим в памяти место под информацию об играх:

Dim Игра(1 To 30) As типИгра

Private Sub Form_Load()

Игра(8).Персонаж(12).Имя = "Солдат"

Игра(8).Персонаж(12).Здоровье = 140

Debug.Print Игра(8).Персонаж(12).Имя, Игра(8).Персонаж(12).Здоровье

End Sub

Если вы захотите более подробно описать оружие, то можете создать еще один пользовательский тип. И так далее. Массивы и пользовательские типы могут вкладываться друг в друга, как матрешки, до бесконечности. Так создаются иерархии данных практически в любой области знаний.

Задание 121: Создайте базу данных о своих родственниках. О каждом родственнике должно быть известно:

• Имя

• Год рождения

• Цвет глаз

Массивы не используйте. Программа должна:

• Распечатать ваш возраст и цвет глаз

• Ответить на вопрос – правда ли, что ваш дядя старше тети.

Задание 122: Создайте базу данных о своих однокашниках. О каждом однокашнике должно быть известно:

• Фамилия

• Имя

• Пол

• Год рождения

Обязательно используйте массив не меньше, чем из 10 записей. Программа должна:

• Вычислить средний возраст ваших однокашников

• Определить, кого среди них больше – дам или кавалеров

• Ответить на вопрос – есть ли в вашей базе тезки (это нелегко).

Базы данных являются настолько распространенным средством хранения информации, что в Visual Basic есть специальные мощные инструменты для работы с ними. Мы рассмотрим их в Глава 9..