Приложение 10. Компьютерная программа расчета параметров сетевого графика

5 CLS:PRINT"РАСЧЕТ ПАРАМЕТРОВ СЕТЕВОГО ГРАФИКА"

6 FM$="#########.#":FM1$="#######.#":DEFINT I-N

7 PRINT"ВЕДИТЕ ИСХОДНЫЕ ДАННЫЕ":INPUT" ЧИСЛО СОБЫТИЙ = ";M

8 DIM T(M,M)'МАССИВ ДЛИТЕЛЬНОСТИ РАБОТ

9 DIM TR(M),TP(M)'МАССИВЫ РАННИХ И ПОЗДНИХ СРОКОВ СВЕРШ.СОБЫТ.

15 FOR I=1 TO M-1

16 CLS:LOCATE 5,35

17 COLOR 5,2:PRINT"ЕСЛИ РАБОТЫ НЕТ, ТО ВВОДИТЕ НОЛЬ"

18 COLOR 7,0,0:LOCATE 8,1,0

19 FOR J=I+1 TO M

20 PRINT"ДЛИТ.РАБОТ T("I","J")";:INPUT T(I,J):IF T(I,J)=0 THEN T(I,J)=1E10

25 NEXT J:NEXT I

30 CLS

32 FOR I=1 TO M:TR(I)=0:TP(I)=1E6:NEXT I

35 'РАСЧЕТ РАННИХ СРОКОВ СВЕРШЕНИЯ СОБЫТИЙ

40 FOR I=1 TO M-1:FOR J=I+1 TO M

45 IF T(I,J)>100000! THEN 50

47 TT=TR(I)+T(I,J):IF TT>TR(J) THEN TR(J)=TT

50 NEXT J:NEXT I

55 'РАСЧЕТ ПОЗДНИХ СРОКОВ СВЕРШЕНИЯ СОБЫТИЙ

60 TP(M)=TR(M):TKR=TP(M)

70 FOR J=M TO 2 STEP -1:FOR I=J-1 TO 1 STEP -1

75 IF T(I,J)>100000! THEN 80

77 TT=TP(J)-T(I,J):IF TT<TP(I) THEN TP(I)=TT

80 NEXT I:NEXT J

85 PRINT" РАСЧЕТ ПАРАМЕТРОВ СЕТЕВОГО ГРАФИКА"

90 PRINT "№ СОБЫ- РАНН.СРОК ПОЗДН.СРОК РЕЗЕРВ"

94 PRINT " ТИЯ СВЕРШЕНИЯ СВЕРШЕНИЯ ВРЕМЕНИ"

100 FOR I=1 TO M:PRINT I;:

102 PRINT USING FM$;TR(I),TP(I),TP(I)-TR(I):NEXT I

105 PRINT"КРИТИЧЕСКОЕ ВРЕМЯ ГРАФИКА- " USING FM$;TKR

110 'РАСЧЕТ ПОЛНЫХ И СВОБОДНЫХ РЕЗЕРВОВ РАБОТ

112 PRINT" Р Е З Е Р В Ы Р А Б О Т"

113 PRINT"НАЧАЛЬН. КОНЕЧН. ДЛИТ. ПОЛНЫЙ СВОБОДН."

114 PRINT"СОБЫТ. СОБЫТ. РАБОТЫ РЕЗЕРВ РЕЗЕРВ

115 PRINT"РАБОТЫ РАБОТЫ РАБОТЫ РАБОТЫ

116 FOR I=1 TO M-1:FOR J=I+1 TO M

120 IF T(I,J)>100000! THEN 150

125 PRINT I,J;:

130 PRINT USING FM1$;T(I,J),TP(J)-TR(I)-T(I,J),TR(J)-TR(I)-T(I,J)

150 NEXT J:NEXT I

200 END

Приложение 11. Компьютерная программа решения игровой задачи двух сторон на основе алгоритма брауна

CLS

PRINT "МОДЕЛИРОВАНИЕ ИГРЫ ПО АЛГОРИТМУ БРАУНА"

PRINT"ВВЕДИТЕ ИСХОДНЫЕ ДАННЫЕ"

FM1$="######.##":FM2$="#.####"

INPUT"ЧИСЛО СТРАТЕГИЙ СТОРОНЫ А";M

INPUT"ЧИСЛО СТРАТЕГИЙ СТОРОНЫ В";N

INPUT"ТОЧНОСТЬ РЕШЕНИЯ Е";E

IF M>N THEN MN=M ELSE MN=N

DIM C(M,N),CP(MN),CN(M),CM(N),IA(10000),IB(10000),SB(M),CA(N),A(M),B(N)

'ВВОД ДАННЫХ

PRINT"ЦЕНУ ИГРЫ ДЛЯ СТРАТЕГИЙ ИГРОКОВ"

FOR I=1 TO M :FOR J=1 TO N

PRINT" C(A("I"),B("J"))=";

INPUT C(I,J)

NEXT J:NEXT I

JI=0

JI=JI+1

'НАЧАЛЬНОЕ РЕШЕНИЕ

MNP=N:IZN=1

FOR I=1 TO M

FOR J=1 TO N: CP(J)=C(I,J)

NEXT J

GOSUB 1000:CN(I)=CP(IPP)

NEXT I

MNP=M:IZN=-1

FOR J=1 TO N

FOR I=1 TO M: CP(I)=C(I,J)

NEXT I

GOSUB 1000:CM(J)=CP(IPP)

NEXT J

FOR I=1 TO M

CP(I)=CN(I)

NEXT I

MNP=M

IZN=-1

GOSUB 1000:IA(JI)=IPP

FOR J=1 TO N

CP(J)=CM(J)

NEXT J

MNP=N

IZN=+1

GOSUB 1000:IB(JI)=IPP

IF ABS(CM(IB(JI))-CN(IA(JI)))>0 THEN 800

PRINT "ИМЕЕТСЯ СЕДЛОВАЯ ТОЧКА С ЦЕНОЙ "CM(IB(JI)):GOTO 3000

'РАСЧЕТ НАКОПЛЕННЫХ РЕЗУЛЬТАТОВ СТОРОНЫ А

800 PRINT" РЕШЕНИЕ ПРИ" JI"-Й ИТЕРАЦИИ A("IA(JI)") И B("IB(JI)")":PRINT "SA ";

FOR J=1 TO N

SA(J)=SA(J)+C(IA(JI),J):PRINT USING FM1$;SA(J),

NEXT J

PRINT:PRINT "SB ";

'РАСЧЕТ НАКОПЛЕННЫХ РЕЗУЛЬТАТОВ СТОРОНЫ B

FOR I=1 TO M

SB(I)=SB(I)+C(I,IB(JI)): PRINT USING FM1$;SB(I),

NEXT I

PRINT

'РАСЧЕТ ПОСЛЕДУЮЩИХ ИТЕРАЦИЙ

900 JI=JI+1:JP=JI-1

FOR J=1 TO N

CP(J)=SA(J)

NEXT J

MNP=N

IZN=+1

GOSUB 1000:IB(JI)=IPP

FOR I=1 TO M

CP(I)=SB(I)

NEXT I

MNP=M

IZN=-1

GOSUB 1000:IA(JI)=IPP

IF ABS(SA(IB(JI))/JP-SB(IA(JI))/JP)<E THEN 2000

GOTO 800

1000 REM

IPP=1

FOR IP1=2 TO MNP

IF CP(IP1)*IZN<CP(IPP)*IZN THEN IPP=IP1

NEXT IP1

RETURN

'РАСЧЕТ ВЕРОЯТНОСТЕЙ СТРАТЕГИЙ

2000 FOR I=1 TO M

A(I)=0

FOR J=1 TO JP

IF I=IA(J) THEN A(I)=A(I)+1

NEXT J

NEXT I

FOR I=1 TO N

B(I)=0

FOR J=1 TO JP

IF I=IB(J) THEN B(I)=B(I)+1

NEXT J

NEXT I

PRINT "СРЕДНЯЯ ЦЕНА ИГРЫ СТОРОНЫ А ="USING FM1$;SA(IB(JI))/JP

PRINT "СРЕДНЯЯ ЦЕНА ИГРЫ СТОРОНЫ B ="USING FM1$;SB(IA(JI))/JP

PRINT "ЧИСЛО ИТЕРАЦИЙ ="JP

PRINT "ВЕРОЯТНОСТИ СТРАТЕГИЙ"

FOR I=1 TO M

PRINT "A("I")=",USING FM2$;A(I)/JP

NEXT I

FOR I=1 TO N

PRINT "B("I")=",USING FM2$;B(I)/JP

NEXT I

PRINT" SA И SB - СООТВЕТСТВЕННО НАКОПЛЕННЫЕ РЕЗУЛЬТАТЫ СТОРОН А И В"

3000 END

ВВЕДЕНИЕ 3

1. ОСНОВЫ ИССЛЕДОВАНИЯ СИСТЕМ И ПРИНЯТИЯ РЕШЕНИЙ 4

1.1. Постановка задач принятия решений и разработка моделей 4

1.2. Классификация математических моделей и методов принятия решений 5

1.3. Принятие решений в условиях определенности при векторном критерии 6

1.4. Принятие решений в условиях риска и неопределенности 7

1.5. Программное компьютерное обеспечение исследования транспортных систем 10

2. ПОСТРОЕНИЕ МАТЕМАТИЧЕСКИХ МОДЕЛЕЙ 13

2.1. Детерминированные модели 13

2.1.1. Решение систем линейных уравнений 13

2.1.2. Решение систем нелинейных уравнений 14

2.1.3. Численное интегрирование 16

2.1.4. Вычисление специальных функций 17

2.1.5. Сортировка чисел (символов) 20

2.2. Стохастические модели 23

2.2.1. Исследование распределения случайных величин 23

2.2.2. Генерация случайных чисел по различным законам распределения 32

2.2.3. Интервальная оценка параметров и определение интервалов распределения случайных величин 34

2.2.4. Исследование статистических зависимостей между случайными величинами 35

2.2.5. Исследование временных рядов 40

2.2.6. Системы массового обслуживания 41

3. ОПТИМИЗАЦИОННЫЕ ЗАДАЧИ И МЕТОДЫ ИХ РЕШЕНИЯ 52

3.1. Безусловная оптимизация для одномерной унимодальной целевой функции 52

3.2. Многомерная безусловная оптимизация 58

3.3. Оптимизация при наличии ограничений 63

3.4. Задача линейного программирования 66

3.5. Отыскание кратчайших расстояний и путей между пунктами транспортной сети. Кратчайшая связывающая сеть 70

3.6. Транспортная задача линейного программирования 75

3.7. Одномерная задача динамического программирования 86

3.8. Эвристические методы решения транспортных задач 90

3.8.1. Маршрутизация перемещения ресурсов помашинными отправками 90

3.8.2. Маршрутизация перемещения мелких партий ресурсов 92

3.9. Задачи дискретной оптимизации 99

3.9.1. Целочисленная задача линейного программирования 99

3.9.2. Задача о назначениях 100

3.9.3. Задача о ранце (рюкзаке) 100

3.9.4. Задача о коммивояжере 101

3.10. Задачи упорядочения и согласования 107

3.11. Состязательные задачи 111

ПРИЛОЖЕНИЕ 1. КОМПЬЮТЕРНАЯ ПРОГРАММА ПРИНЯТИЯ РЕШЕНИЙ В УСЛОВИЯХ РИСКА И НЕОПРЕДЕЛЕННОСТИ 116

ПРИЛОЖЕНИЕ 2. КОМПЬЮТЕРНАЯ ПРОГРАММА ИССЛЕДОВАНИЯ РАСПРЕДЕЛЕНИЯ СЛУЧАЙНЫХ ВЕЛИЧИН 117

ПРИЛОЖЕНИЕ 3. КОМПЬЮТЕРНАЯ ПРОГРАММА ОДНОФАКТОРНОГО КОРРЕЛЯЦИОННО-РЕГРЕССИОННОГО АНАЛИЗА 126

ПРИЛОЖЕНИЕ 4. КОМПЬЮТЕРНАЯ ПРОГРАММА ПРОВЕДЕНИЯ МНОГОФАКТОРНОГО КОРРЕЛЯЦИОННО-РЕГРЕССИОННОГО АНАЛИЗА 131

ПРИЛОЖЕНИЕ 5. КОМПЬЮТЕРНАЯ ПРОГРАММА ВЫРАВНИВАНИЯ ДИНАМИЧЕСКОГО РЯДА МНОГОЧЛЕНОМ РЯДА ФУРЬЕ 134

ПРИЛОЖЕНИЕ 6. КОМПЬЮТЕРНАЯ ПРОГРАММА РЕШЕНИЯ ЗАДАЧИ ЛИНЕЙНОГО ПРОГРАММИРОВАНИЯ СИМПЛЕКС-МЕТОДОМ 136

ПРИЛОЖЕНИЕ 7. КОМПЬЮТЕРНАЯ ПРОГРАММА ОТЫСКАНИЯ КРАТЧАЙШИХ РАССТОЯНИЙ МЕЖДУ ПУНКТАМИ ТРАНСПОРТНОЙ СЕТИ 137

ПРИЛОЖЕНИЕ 8. КОМПЬЮТЕРНАЯ ПРОГРАММА РЕШЕНИЯ ТРАНСПОРТНОЙ ЗАДАЧИ ЛИНЕЙНОГО ПРОГРАММИРОВАНИЯ 139

ПРИЛОЖЕНИЕ 9. КОМПЬЮТЕРНАЯ ПРОГРАММА РАЗРАБОТКИ СБОРОЧНО-РАЗВОЗОЧНЫХ МАРШРУТОВ НА ОСНОВЕ МЕТОДА КЛАРКА-РАЙТА 145

ПРИЛОЖЕНИЕ 10. КОМПЬЮТЕРНАЯ ПРОГРАММА РАСЧЕТА ПАРАМЕТРОВ СЕТЕВОГО ГРАФИКА 148

ПРИЛОЖЕНИЕ 11. КОМПЬЮТЕРНАЯ ПРОГРАММА РЕШЕНИЯ ИГРОВОЙ ЗАДАЧИ ДВУХ СТОРОН НА ОСНОВЕ АЛГОРИТМА БРАУНА 148