4. Различные статические задачи изгиба и кручения стержневых систем

Возможности конечно-элементного моделирования задач технической механики и сопротивления материалов с использованием ANSYS конечно же не ограничиваются темами, рассмотренными в предыдущих пунктах. В настоящем разделе обсуждаются некоторые другие типы задач и особенности их анализа в ANSYS. Изложение здесь более сжато, так как задания этого раздела предполагают самостоятельную разработку нужных программ, используя документацию по ANSYS [4-8] и приведенные примеры.

4.1. Кручение стержней. При решении задач кручения сопротивления материалов на ANSYS подходящими КЭ являются КЭ BEAM4 и PIPE16. Эти элементы имеют степенями свободы узловые смещения UX, UY, UZ и углы поворота ROTX, ROTY, ROTX в двух концевых узлах. С их помощью можно решать разнообразные задачи растяжения-сжатия, изгиба и кручения стержневых систем (в т.ч. и для сложного напряженного состояния).

Элемент BEAM4 является обобщением плоского балочного элемента BEAM3 на трехмерный случай. Если ось x - продольная ось элемента, то моментом, вызывающим кручение, будет момент MX. Для задач кручения стержней требуется задавать модуль сдвига G=, а также специальную геометрическую характеристику поперечного сечения , которая для кругового сечения совпадает с полярным моментом инерции .В списке констант (Real Constants) для элемента BEAM4 [6] находим моменты инерции IZZ, IXX и IXX на второй, третьей и восьмой позициях списка соответственно. При этом под моментом инерции IXX подразумевается крутящий момент инерции. В [6] указано, что IXX либо задается явно, либо вычисляется по формуле: IXX=IYY+IZZ, если IXX не определен явно, или IXX=0. Для задания IXX можно использовать команду RMORE, R7,R8,..., R12 в виде RMORE,,IXX или команду RMODIF.

Для стержней круглого сечения предпочтительнее использовать «трубчатый» КЭ PIPE16. Этот элемент представляет собой полую трубку, и для сплошного круглого стержня следует просто задать толщину трубки, равную радиусу сечения. Среди констант элемента (Real Constants) достаточно определить внешний диаметр OD и толщину стенки TKWALL : R,NSET,OD,TKWALL .

В качестве примера рассмотрим задачу 4.33 из [3]. Здесь стальной стержень круглого сечения с защемленными торцами скручивается двумя равными и одинаково направленными моментами M=8e4 (кГ ). Геометрические данные задачи следующие: диаметр стержня d=10 см; a=60 см; b=80 см. Требуется определить реакции в заделках и угол закручивания в сечении x=a+b/2 (рис. 4.1).

Рис. 4.1.

Программа SMs4.inp, решающая данную задачу, приводится ниже.

/batch ! Пакетный режим /BATCH

/com,

/com, Файл SMs4.inp

/com, ПРОГРАММА РЕШЕНИЯ ЗАДАЧИ СОПРОТИВЛЕНИЯ МАТЕРИАЛОВ

/com, ПО ТЕМЕ: "КРУЧЕНИЕ"

/com, (версия 1.2)

/com,

/com, Сборник задач по сопротивлению материалов /

/com, Под ред. В.К. Качурина. М.: Наука, 1970.

/com, (по задаче 4.33. С.94.)

/com,

/com, Два варианта конечных элементов - BEAM4 и PIPE16

/com,

/com, Итоговые результаты записываются

/com, в файл вывода SMs4.res

/com,

/title, TORSION OF A CIRCULAR ROD

F_R='SMs4' ! Имя файла для вывода результатов

/prep7 ! Входим в препроцессор /PREP7

! Все данные в системе СГС

pi=3.1416

dr=10 ! dr - диаметр стержня

ar=60 ! ar, b2r - геометрические параметры

b2r=40

jpol=pi*dr**4/32 ! константа для полярного момента инерции

et,1,beam4 ! балочные КЭ BEAM4

r,1,pi*dr**2/4,jpol/2 ! REAL CONST :

! площадь поперечного сечения AREA=pi*dr**2/4 ,

! момент инерции IZZ=jpol/2

rmore,,jpol ! полярный момент инерции

! (8-ая REAL-константа для BEAM4)

mp,ex,1,2e6 ! модуль Юнга EX=2e6

mp,gxy,1,8e5 ! модуль сдвига GXY=8e5

n,1 ! Определяем узлы по координатам

n,2,ar

n,3,ar+b2r

n,4,ar+b2r*2

n,5,(ar+b2r)*2

*do,i,1,4 ! Определяем элементы BEAM4

e,i,i+1

*enddo

finish

/solu ! Входим в решатель /SOLUTION

antype,static ! Статический тип анализа

d,1,all,0,,5,4 ! Задаем условия закрепления в узлах

f,2,mx,8e4 ! Задаем крутящие моменты в узлах

f,4,mx,8e4

outpr,basic,1 ! Вывод основных результатов в стандартный файл

solve ! Решаем СЛАУ МКЭ

finish

/post1

rot_middle=rotx(3)

/output,F_R,res ! Направляем вывод в файл <F_R>.res

*VWRITE

(1X,' TORSION OF A CIRCULAR ROD')

*VWRITE

(1X,' FINITE ELEMENT beam4')

*VWRITE,rot_middle

(1X,' rot_middle=', E12.5 )

PRRSOL ! Печатаем опорные реакции

/output

/prep7 ! Вариант с КЭ PIPE16

et,1,pipe16 ! КЭ - трубки PIPE16

r,1,dr,dr/2 ! REAL CONST :

! внешний диаметр сечения OD=dr,

! толщина стенок трубы TKWALL=dr/2

! (сплошная труба)

finish

/solu

solve

finish

/post1

rot_middle=rotx(3)

/output,F_R,res,,append ! Направляем вывод в файл <F_R>.res

*VWRITE

(1X,' FINITE ELEMENT pipe16')

*VWRITE,rot_middle

(1X,' rot_middle=', E12.5 )

PRRSOL ! Печатаем опорные реакции

/output

/exit

В результате выполнения программы в файле SMs4.res среди различной выводной информации найдем значения угла закручивания =0.61115e-2 (рад) и реактивных моментов MX=-8e4 (кГ ), что совпадает с ответом к задаче из [3].

Вариант интерактивного решения данной задачи приводится ниже.

ПРОГРАММА РЕШЕНИЯ ЗАДАЧИ СОПРОТИВЛЕНИЯ МАТЕРИАЛОВ

ПО ТЕМЕ: "КРУЧЕНИЕ"

1. Заголовок задачи

1.1. Utility Menu>File>Change Title

1.2. Набрать заголовок «TORSION OF A CIRCULAR ROD »

1.3. OK

2. Входим в препроцессор /PREP7

2.1. Main Menu>Preprocessor

Все данные в системе СГС

3. Введение параметров для построения геометрии

3.1. Utility Menu>Parameters>Scalar Parameters

3.2. В появившемся окне в строке раздела Selection ввести имена и значения параметров (после набора каждого параметра – Accept):

pi=3.1416

dr=10 (диаметр стержня)

ar=60

b2r=40

jpol=pi*dr**4/32 ( константа для полярного момента инерции)

3.3. Close

3. Выбор типа конечных элементов (балочные КЭ BEAM4)

3.1. Main Menu>Preprocessor>Element Type>Add/Edit/Delete

3.2. Выбрать «Add»

3.3. Пролистать список библиотеки элементов вниз и выбрать «Structural Beam». Из крайнего справа списка выбрать «3D elastic 4»

3.4. OK

3.5. Close

3.6. Закрыть окно «Element Type»

4. Задание реальных констант (геометрических характеристик) REAL=1

4.1. Main Menu>Preprocessor>Real Constants>Add/Edit/Delete

4.2. Выбрать «Add»

4.3. Появляется окно «Element Type for Real Constants» с предлагаемым списком элементов

«Type 1 BEAM4»

4.4. OK

4.5. Появляется окно «Real Constant for Beam4»

Cross-sectional area AREA  pi*dr**2/4 (площадь поперечного сечения)

Area moment of inertia IZZ  jpol/2 ( момент инерции)

Torsional moment of inertia IXX jpol (полярный момент инерции)

4.6. OK

4.7. Close

5. Задание материальных свойств (Модуль Юнга материалов стержней EX=2e6 и модуль сдвига GXY=8e5)

5.1. Main Menu>Preprocessor>Material Props>Material Models

(появляется диалоговое окно «Define Material Model Behavior»)

5.2. В окне «Material Models Available » двойной щелчок левой кнопкой мыши на следующих окошках: Structural, Linear, Elastic, Isotropic.

5.3. В поле для «EX» ввести 2e6

В поле для «GXY» ввести 8e5

5.4. OK

5.5. Закрыть окно «Define Material Model Behavior», выбрав Material>Exit или х.

5.6. Закрыть окно «Material Props»

6. Определяем узлы по координатам

6.1. Main Menu>Preprocessor>Modeling>Create>Nodes>In Active CS

6.2. Используя окно «Create Nodes in Active Coordinate System», задать узлы

NODE Node number  1

X,Y,Z Location in active CS  0, 0

(координату Z не задаем явно, и поэтому она будет всюду равна нулю)

Apply

NODE Node number  2

X,Y,Z Location in active CS  ar, 0

(здесь и далее при задании координат узлов используются параметры, введенные ранее)

Apply

NODE Node number  3

X,Y,Z Location in active CS  ar+b2r, 0

Apply

NODE Node number  4

X,Y,Z Location in active CS  ar+b2r*2, 0

Apply

NODE Node number  5

X,Y,Z Location in active CS  (ar+b2r)*2, 0

6.3.ОК

7. Определение элементов BEAM4 в цикле

7.1. Создаем предварительно файл с произвольным именем (например, F_R1.txt) и заносим в него следующие строки:

*do,i,1,4

e,i,i+1

*enddo

7.2. Utility Menu>File> Read Input from

7.3. В окне «Read File», выбрать файл F_R1.txt

7.4. OK

(три приведенных выше строки оператора цикла можно также выполнить в командной строке ANSYS)

8. Main Menu>Finish (или просто закрываем Preprocessor)

9. Входим в решатель /SOLUTION

Main Menu>Solution

10. Статический тип анализа

10.1. Main Menu>Solution>Analysis Type>New Analysis

10.2. В открывшемся окне отметить:

[ANTYPE] Type of analysis  Static

10.3. OK

(шаг 10 не обязателен, так как данные установки были бы приняты по умолчанию)

11. Задаем условия закрепления

11.1. Определяем опоры в узлах

Main Menu> Solution >Define Loads> Apply>Structural>Displacement>On Nodes

11.2. Слева появляется окно «Apply U,ROT on Nodes»

11.3. Нажатием левой кнопки мыши в графическом окне пометить узел 1 и 5

Apply,

11.4. В открывшемся окне задать значения:

Lab2 DOFs to be constrained  All DOF

VALUE Displacement value  0

11.5. OK

12. Задаем крутящие моменты в узлах

12.1. Main Menu> Solution>Define Loads> Apply>Structural>Force/Moment>On Nodes

12.2. Слева появляется окно «Apply F/M Nodes»

12.3. Нажатием левой кнопки мыши в графическом окне пометить узел 2 и узел 4 Apply,

12.4. В открывшемся окне задать значения:

Lab Direction of force/mom MX

VALUE Force/moment value 8e4

12.5. OK

13. Решить СЛАУ МКЭ

13.1. Main Menu>Solution>-Solve-Current LS

13.2. OK

14. Завершение работы решателя

14.1. Main Menu>Finish (или просто закрыть Solution)

15. Входим в постпроцессор /POST1

Main Menu>General Postproc

16. Печать опорных реакций

16.1. Main Menu>General Postproc>List Results>Reaction Solu

16.2. В открывшемся окне выбираем:

Lab Item to be listed  All items

16.3. OK

16.4. Вывод опорных реакций в окне PRRSOL можно сохранить в файл через подменю File, Save as..

17. Печать углов поворота в узлах

17.1. Main Menu>General Postproc>List Results>Nodal Solution> Nodal Solution > DOF solution > Rotation vector sum

17.2. В появившемся окошке нажать OK

17.3. Вывод результатов в окне PRNSOL можно теперь сохранить в файл через подменю File, Save as..

18. Завершение работы постпроцессора

Main Menu>Finish (или просто закрыть General Postproc)

Вариант с КЭ PIPE16

19. Входим в препроцессор /PREP7

19.1. Main Menu>Preprocessor

20. КЭ - трубки PIPE16

20.1. Main Menu>Preprocessor>Element Type>Add/Edit/Delete

20.2. Выбрать «Add»

20.3. Пролистать список библиотеки элементов вниз и выбрать «Structural Pipe». Из крайнего справа списка выбрать «Elast straight 16»

20.4. OK

20.5. Close

20.6. Закрыть окно «Element Type»

21. Определения новых значений реальных (геометрических) констант

21.1. Main Menu>Preprocessor>Real Constants

21.2. Выбрать «Add»

21.3. Появляется окно «Element Type for Real Constants»

21.4. OK

21.5. Появляется окно «Real Constant for Pipe16»

Outside diameter OD  dr (внешний диаметр сечения)

Wall thickness TKWALL  dr/2 ( толщина стенок трубы ( сплошная труба))

21.6. OK

21.7. Close

22. Main Menu>Finish (или просто закрываем Preprocessor)

23. Входим в решатель /SOLUTION

23.1. Main Menu>Solution

24. Решить СЛАУ МКЭ

24.1. Main Menu>Solution>-Solve-Current LS

24.2. OK

25. Завершение работы решателя

25.1. Main Menu>Finish (или просто закрыть Solution)

26-29. Дальнейший просмотр результатов в постпроцессоре осуществляется аналогично шагам 15-18

30. Выход

Utility Menu>File>Exit

OK

2. Кривые стержни. Для расчета кривых стержней круглого сечения в ANSYS существует КЭ PIPE18. Этот элемент представляет собой искривленную полую трубку, отличаясь от КЭ PIPE16 именно наличием кривизны. При расчете кривых стержней с помощью элемента PIPE18 в списке констант КЭ требуется задать следующие величины: внешний диаметр OD, толщину стенки TKWALL и радиус кривизны RADCUR. Для этого используется команда: R,NSET,OD,TKWALL,RADCUR. При формировании элемента PIPE18 необходимы три узла: два граничных узла и узел, определяющий положение центра кривизны элемента. Если не требовать большого сервиса, то программа расчета кривых стержней может быть похожа на приведенную ранее программу SMs4.inp. Например, для задачи № 11.18 из [3] такая программа может иметь следующий вид.

/batch ! Пакетный режим /BATCH

/com,

/com, Файл SMs5.inp

/com, ПРОГРАММА РЕШЕНИЯ ЗАДАЧИ СОПРОТИВЛЕНИЯ МАТЕРИАЛОВ

/com, ПО ТЕМЕ: "КРИВЫЕ СТЕРЖНИ"

/com, (версия 1.2 программы без построения эпюр)

/com,

/com, Сборник задач по сопротивлению материалов /

/com, Под ред. В.К. Качурина. М.: Наука, 1970.

/com, (по задаче 11.18. С.331.)

/com,

/com, Итоговые результаты записываются

/com, в файл вывода SMs5.res

/com,

/title, CURVED BAR

F_R='SMs5' ! Имя файла для вывода результатов

/prep7 ! Входим в препроцессор /PREP7

! Все данные в системе СГС

dr=2 ! dr - диаметр стержня

ar=10 ! ar - радиус кривизны

et,1,pipe18 ! КЭ - искривленные трубки PIPE18

keyopt,1,6,2 ! печать внутренних усилий

r,1,dr,dr/2,ar ! REAL CONST :

! внешний диаметр сечения OD=dr,

! толщина стенок трубы TKWALL=dr/2

! (сплошная труба)

! радиус кривизны RADCUR=ar

mp,ex,1,2e6 ! модуль Юнга EX=2e6

mp,gxy,1,8e5 ! модуль сдвига GXY=8e5

n,1 ! Определяем узлы и элементы

n,2,-ar

n,3,0,ar

n,4,ar

e,2,3,1 $ e,3,4,1

finish

/solu ! Входим в решатель /SOLUTION

antype,static ! Статический тип анализа

d,all,uz,0 ! Задаем условия закрепления в узлах

d,2,ux,0 $ d,2,uy,0

d,4,ux,0 $ d,4,uy,0

f,3,fy,-100 ! Задаем силу в узле 2+n_fill

outpr,basic,1 ! Вывод основных результатов в стандартный файл

solve ! Решаем СЛАУ МКЭ

finish

/post1

/output,F_R,res ! Направляем вывод в файл <F_R>.res

prrsol ! Печатаем опорные реакции

/output

finish

/exit

Вариант интерактивного решения данной задачи приводится ниже.

ПРОГРАММА РЕШЕНИЯ ЗАДАЧИ СОПРОТИВЛЕНИЯ МАТЕРИАЛОВ

ПО ТЕМЕ: "КРИВЫЕ СТЕРЖНИ" (версия программы без построения эпюр)

1. Заголовок задачи

1.1. Utility Menu>File>Change Title

1.2. Набрать заголовок « CURVED BAR »

1.3. OK

2. Входим в препроцессор /PREP7

2.1. Main Menu>Preprocessor

Все данные в системе СГС

3. Введение параметров для построения геометрии

3.1. Utility Menu>Parameters>Scalar Parameters

3.2. В появившемся окне в строке раздела Selection ввести имена и значения параметров (после набора каждого параметра – Accept):

dr=2 (диаметр стержня)

ar=10 (радиус кривизны)

3.3. Close

4. Выбор типа конечных элементов (КЭ - искривленные трубки PIPE 18)

4.1. Main Menu>Preprocessor>Element Type>Add/Edit/Delete

4.2. Выбрать «Add»

4.3. Пролистать список библиотеки элементов вниз и выбрать «Structural Pipe». Из крайнего справа списка выбрать «Elast elbow 18»

4.4. OK

4.5. Close

5. Печать внутренних усилий

5.1. Main Menu>Preprocessor>Element Type>Add/Edit/Delete

5.2. В окне «Element Types» выбрать «Options»

5.3. После нажатия этой кнопки появляется окно «PIPE18 element type options»

5.4. Поставим значение:

Member force + moment output K6  Include output

5.4. OK

5.5. Close

5.6. Закрыть окно «Element Type»

6. Задание реальных констант (геометрических характеристик) REAL=1

6.1. Main Menu>Preprocessor>Real Constants

6.2. Выбрать «Add»

6.3. Появляется окно «Real Constants»

6.4. OK

6.5. Появляется окно «Real Constant Set Number 1, for Pipe18»

Outside diameter OD  dr (внешний диаметр сечения)

Wall thickness TKWALL  dr/2 ( толщина стенок трубы)

Radius of curvature RADCUR  ar (радиус кривизны)

6.6. OK

6.7. Close

7. Задание материальных свойств (Модуль Юнга материалов стержней EX=2e6 и модуль сдвига GXY=8e5)

7.1. Main Menu>Preprocessor>Material Props>Material Models

(появляется диалоговое окно «Define Material Model Behavior»)

7.2. В окне «Material Models Available » двойной щелчок левой кнопкой мыши на следующих окошках: Structural, Linear, Elastic, Isotropic.

7.3. В поле для «EX» ввести 2e6

В поле для «GXY» ввести 8e5

7.4. OK

7.5. Закрыть окно «Define Material Model Behavior», выбрав Material>Exit или х.

7.6. Закрыть окно «Material Props»

8. Определяем узлы по координатам

8.1. Main Menu>Preprocessor>Modeling>Create>Nodes>In Active CS

8.2. Используя окно «Create Nodes in Active Coordinate System», задать узлы

NODE Node number  1

X,Y,Z Location in active CS  0, 0

(координату Z не задаем явно, и поэтому она будет всюду равна нулю)

Apply

NODE Node number  2

X,Y,Z Location in active CS - ar, 0

(здесь и далее при задании координат узлов используются параметры, введенные ранее)

Apply

NODE Node number  3

X,Y,Z Location in active CS  0, ar

Apply

NODE Node number  4

X,Y,Z Location in active CS  ar, 0

Apply

8.3. ОК

9. Определяем элементы

9.1. Main Menu>Preprocessor>Create>Elements>Thru Nodes

9.2.Слева появляется окно «Elements from Nodes».

Нажатием левой кнопки мыши в графическом окне пометить узел 2 и соединить его с узлом 3, затем с узлом 1 Apply,

затем – узел 3 с узлом 4, и узлом 1 Apply

9.3.OK

10. Main Menu>Finish (или просто закрываем Preprocessor)

11.Входим в решатель /SOLUTION

Main Menu>Solution

12. Статический тип анализа

12.1. Main Menu>Solution>Analysis Type>New Analysis

12.2. В открывшемся окне отметить:

[ANTYPE] Type of analysis  Static

12.3. OK

(шаг 12 не обязателен, так как данные установки были бы приняты по умолчанию)

13. Задаем условия закрепления в узлах

13.1. Main Menu> Solution >Define Loads> Apply>Structural>Displacement>On Nodes

13.2.Слева появляется окно «Apply U,ROT on Nodes»

13.3. Нажимаем кнопку Pick All

13.4. Появляется окно «Apply U,ROT on Nodes»

13.5. Выбираем значения:

Lab2 DOFs to be constrained  UZ

VALUE Displacement value  0

13.6. Apply

13.7. Нажатием левой кнопки мыши в графическом окне пометить узел 2 Apply,

13.8. В открывшемся окне задать значения:

Lab2 DOFs to be constrained  UY, UX

VALUE Displacement value  0

13.9. Apply

13.10. Затем пометить узел 4

13.11. Apply

13.12. В открывшемся окне задать значения:

Lab2 DOFs to be constrained  UY, UX

VALUE Displacement value  0

13.13. OK

14. Задаем силу в узле 3

14.1. Main Menu> Solution >Define Loads> Apply>Structural>Force/Moment>On Nodes

14.2. Слева появляется окно «Apply F/M Nodes»

14.3. Нажатием левой кнопки мыши в графическом окне пометить узел 3 Apply,

14.4. В открывшемся окне задать значения:

Lab Direction of force/mom FY

VALUE Force/moment value -100

14.5. OK

15. Вывод основных результатов в стандартный файл

15.1. Main Menu>Solution>Output Ctrls>Solu Printout

15.2. В окне «Solution Printout Controls» выбрать:

Item Item for printout control  Basic quantities

FREQ Print frequency  Every Nth substp