6. Метод наименьших квадратов

Результаты экспериментальных исследований для дальнейшего анализа удобно представить в графическом виде. Часто функциональные зависимости между переменными линейны, либо определенной заменой переменных зависимость удается привести к линейному виду. Например, исследуя равноускоренное одномерное движение тела, мы определяем координату тела в разные моменты времени: Координаты и соответствующие моменты времени связаны функциональной зависимостью:

где - начальная координата тела, - начальная скорость. Перепишем данную зависимость в следующем виде:

Если ввести переменную , то можно видеть, что зависимость s(t) - линейна. Нанесем экспериментальные точки на график и проведем через них прямую (рис.1).

Рис.1

Тангенс угла наклона данной прямой к оси равен половине ускорения, с каким двигалось тело, а отрезок, отсекаемый прямой на оси , дает величину начальной скорости тела.

Экспериментальные точки, как правило, не лежат в точности на прямой. Возникает естественный вопрос: как наилучшим образом провести прямую через эти точки? Если проводить прямую "на глазок", то при большом разбросе экспериментальных точек прямые, проведенные разными людьми, могут значительно отличаться друг от друга наклоном этих прямых и величиной отрезка, отсекаемого на оси ординат. То есть, такой способ весьма субъективен. К тому же он не дает возможности оценить погрешности определяемых величин (в случае рис.1 - ускорения и начальной скорости).

Наибольшее распространение получил так называемый метод наименьших квадратов (МНК). Суть его заключается в следующем. Будем аппроксимировать экспериментальную зависимость прямой , где и - некоторые пока неизвестные коэффициенты. Проведем через точки произвольную прямую (рис.2).

Рис.2

Из каждой точки проведем вертикальную прямую до пересечения с нашей прямой. Полученные отрезки - от точек до прямой - назовем отклонениями от прямой. На рис.2 это будут отрезки длиной , , , .

Величина i-го отклонения равна:

.

Если менять параметры и прямой, то и длины отрезков будут меняться. Критерий наилучшего проведения прямой в методе наименьших квадратов таков: сумма квадратов отклонений должна быть минимальной:

Или:

Минимум этой суммы достигается подбором параметров прямой и . Математический анализ легко справляется с такой задачей и дает следующие выражения для данных параметров:

где

Кроме того, вычисляются следующие величины.

Среднеквадратичное отклонение точек от прямой:

где

Погрешности коэффициентов и :

Ниже приводится программа расчета параметров прямой методом МНК. Программа составлена на языке BASIC. При желании ее легко переписать на любом другом языке программирования.

Обозначены суммы: ; ; ; ; В строках 100-140 происходит вычисление этих сумм. В последующих строках вычисляются параметры прямой, обозначенные:

10 DIM X(50),Y(50)

20 PRINT "ЧИСЛО ТОЧЕК N =";

30 INPUT N

40 FOR I = 1 TO N

50 PRINT: PRINT "I ="; I

60 PRINT "X="; : INPUT X(I)

70 PRINT "Y="; : INPUT Y(I)

80 NEXT I

90 X1 = 0: X2 = 0: Y1 = 0: Y2 = 0: S = 0

100 FOR I = 1 TO N

110 X1 = X1 + X(I): X2 = X2 + X(I)^2

120 Y1 = Y1 + Y(I): Y2 = Y2 + Y(I)^2

130 S = S + X(I) * Y(I)

140 NEXT I

150 D = N * X2 - X1 * X1

160 A = (N * S - X1 * Y1) / D

170 B = (Y1 - A * X1) / N

180 F = Y2 - A * S - B * Y1

190 D1 = SQR(F / (N - 2))

200 A1 = D1 * SQR(N / D)

210 B1 = D1 * SQR(X2 / D)

220 PRINT "*******************************************"

230 PRINT "Y = A*X + B"

240 PRINT "A ="; A; TAB(20); "DA ="; A1

250 PRINT "B ="; B; TAB(20); "DB ="; B1

260 PRINT "DELTA ="; D1

Для демонстрации работы программы обратимся к лабораторной работе №3 "Маятник Обербека".

В работе экспериментально проверяется формула

,

где - угловое ускорение маятника, - момент инерции маятника,

- момент силы трения, - внешний момент, приводящий к

вращению маятника.

Перепишем данную формулу в следующем виде: ,

где , , , .

Числовые значения переменных и даны в таблице:

227	0,650
243	0,695
259	0,745
211	0,590
195	0,535

Результаты расчета на компьютере:

***************************************

Y = A*X+B

A = 32.8123 DA = .938343

B = -.10184 DB = .0214059

DELTA = 4.74768E-03

Находим момент инерции маятника:

Погрешность момента инерции:

В итоге:

Момент силы трения:

Погрешность момента силы трения:

В итоге:

Среднеквадратичное отклонение точек от прямой

характеризует погрешность определения углового ускорения.