Прога / tina-2.5.2 / nets / FORMATSfr

Formats:
--------

Quatre formats sont utilis'es par les outils Tina:

.net : rйseau temporel sous forme textuelle
.ndr : rйseau temporel sous forme graphique
.aut : automate sous forme textuelle
.adr : automate sous forme graphique


Format .net :
-------------

Un rйseau est dйcrit par une suite de dйclarations de places et/ou de
transitions, et d'une dйclaration optionnelle de nom de rйseau. Le
rйseau dйcrit est la superposition de ces dйclarations. La grammaire
est la suivante. Les non-terminaux sont entre crochets, les terminaux
en majuscule ou entre quotes ('). Espaces et tabulations agissent
comme sйparateurs.

.net ::= (<trdesc>|<pldesc>)* {<netdesc>} (<trdesc>|<pldesc>)*
netdesc ::= 'net' <net>
trdesc ::= 'tr' <transition> {<intervalle>} {<tentrйe> -> <tsortie>}
pldesc ::= 'pl' <place> {(<marquage>)} {<pentrйe> -> <psortie>}
intervalle ::= ('['|']')INT','INT('['|']') | ('['|']')INT','w['
tentrйe, tsortie ::= ( <place>{'*'<poids>})*
pentrйe, psortie ::= ( <transition>{'*'<poids>})*
poids, marquage ::= INT{'K'|'M'}
net, place, transition ::= ANAME | '{'QNAME'}'
INT ::= entier sans signe
ANAME ::= nom alphanumerique, voir Notes ci-dessous
QNAME ::= nom arbitraire, voir Notes ci-dessous

Notes:
Les noms de rйseau, place ou transition ont l'une des formes suivantes:
- ANAME : toute chaine non vide de lettres, chiffres, primes ''' et soulignй '_'
- '{'QNAME'}' : toute chaine de caractиres entre accolades, et dans laquelle tout '{', '}',
et '\' est prйfixй par '\'
Toute ligne vide ou commencant par # est considйrйe comme commentaire.
Dans toute intervalle temporel fermй [eft,lft], on doit avoir eft <= lft.
La lettre 'K' (resp. 'M') suivant un poids ou un marquage multiplie celui-ci par 10^3 (resp. 10^6).
Par dйfaut:
- les transitions ont pour intervalle temporel [0,w[
- les arcs ont le poids 1
- les places sont non marquйes


Format .ndr:
------------

Cґest le format des fichiers produits par lґediteur nd. Un rйseau est
dйcrit par une suite de dйclarations de places, de transitions, et
d'arcs. Le rйseau dйcrit est la superposition de ces dйclarations.

.ndr ::= (<trdesc>|<pldesc>)* (<edgedesc>)* <netdesc>
trdesc ::= 't' <xpos> <ypos> <transition> <eft> <lft> <ancre>
pldesc ::= 'p' <xpos> <ypos> <place> <marquage> <ancre>
edgedesc ::= 'e' <place> <rad> <ang> <transition> <rad> <ang> <weight> <ancre> |
'e' <transition> <rad> <ang> <place> <rad> <ang> <weight> <ancre>
netdesc ::= 'h' <net>
eft ::= {-}INT
lft ::= {-}INT | 'w'
poids, marquage ::= INT{'K'|'M'}
xpos, ypos, rad ::= FLOAT
ang ::= UFLOAT
net, place, transition ::= ANAME | '{'QNAME'}'
ancre ::= 'n' | 'nw' | 'w' | 'sw' | 's' | 'se' | 'e' | 'ne'
FLOAT ::= flottant (sans exposant)
UFLOAT ::= flottant entre 0 et 1 (sans exposant)
INT ::= entier sans signe
ANAME ::= comme pour .net
QNAME ::= comme pour .net

Notes:
Un eft ou lft commencant par '-' dйsigne une extrйmitй d'intervalle ouverte.
Dans toute description de transition, on doit avoir `lft >= `eft ou lft = 'w',
oъ `e dйsigne soit e (si e>=0), soit (-e)-1 (sinon).
Si eft=lft, alors ils ne peuvent кtre tous deux nйgatifs (les intervalles ne
peuvent кtre vides).
Les declarations de noeuds prйcиdent les dйclaration dґarcs.
La dйclaration de nom de rйseau termine la description.
Toute ligne vide ou commencant par # est considйrйe comme commentaire.
La lettre K (resp. M) suivant un poids ou un marquage multiplie celui-ci par 10^3 (resp. 10^6).


Format .aut:
------------

Cґest le format de description dґautomates de lґoutil aldebaran (voir documentation aldebaran).


Format .adr:
------------

Comme .ndr, sauf que les trdesc et pldesc sont remplacйes par stdesc
ci-dessous, et edgedesc est redйfinie comme suit:

stdesc ::= 's' <xpos> <ypos> <state> <ancre>
edgedesc ::= 'e' <state> <rad> <ang> <state> <rad> <ang> <label> <ancre>
state, label ::= ANAME | '{'QNAME'}'