Прога / tina-2.5.2 / nets / FORMATS

Formats:
--------

Four file formats are used by the Tina tools:

.net : Time Petri net in textual form
.ndr : Time Petri net in graphical form
.aut : automaton in textual form
.adr : automaton in graphical form


.net Format:
------------

A net is described by a series of declarations of places and/or
transitions, and an optional naming declaration for the net. The net
described is the superposition of these declarations. The grammar of
.net declarations is the following, in which nonterminals are
bracketed by < .. >, terminals are in upper case or between
quotes. Spaces and tabs act as separators.

.net ::= (<trdesc>|<pldesc>)* {<netdesc>} (<trdesc>|<pldesc>)*
netdesc ::= 'net' <net>
trdesc ::= 'tr' <transition> {<interval>} {<tinput> -> <toutput>}
pldesc ::= 'pl' <place> {(<marking>)} {<pinput> -> <poutput>}
interval ::= ('['|']')INT','INT('['|']') | ('['|']')INT','w['
tinput, toutput ::= ( <place>{'*'<weight>})*
pinput, poutput ::= ( <transition>{'*'<weight>})*
weight, marking ::= INT{'K'|'M'}
net, place, transition ::= ANAME | '{'QNAME'}'
INT ::= unsigned integer
ANAME ::= alphanumeric name, see Notes below
QNAME ::= arbitrary name, see Notes below

Notes:
Two forms are admitted for net, place and transition names:
- ANAME : any non empty string of letters, digits, primes ''' and underscores '_'
- '{'QNAME'}' : any chain between braces, and in which characters '{', '}', and '\'
are prefixed by '\'
Empty lines and lines beginning with '#'are considered comments.
In any closed temporal interval [eft,lft], one must have eft <= lft.
The letter 'K' (resp. 'M') following a weight or marking multiplies it by 10^3 (resp. 10^6).
By default:
- transitions have temporal interval [0,w[
- arcs have weight 1
- places have marking 0



.ndr Format:
------------

It is the format of graphic files produced by the nd editor. A net is
described by a series of declarations of places, transitions and
edges, followed by a net name declaration. The net described is the
superposition of these declarations.

.ndr ::= (<trdesc>|<pldesc>)* (<edgedesc>)* <netdesc>
trdesc ::= 't' <xpos> <ypos> <transition> <eft> <lft> <anchor>
pldesc ::= 'p' <xpos> <ypos> <place> <marking> <anchor>
edgedesc ::= 'e' <place> <rad> <ang> <transition> <rad> <ang> <weight> <anchor> |
'e' <transition> <rad> <ang> <place> <rad> <ang> <weight> <anchor>
netdesc ::= 'h' <net>
eft ::= {-}INT
lft ::= {-}INT | 'w'
poids, marking ::= INT{'K'|'M'}
xpos, ypos, rad ::= FLOAT
ang ::= UFLOAT
net, place, transition ::= ANAME | '{'QNAME'}'
anchor ::= 'n' | 'nw' | 'w' | 'sw' | 's' | 'se' | 'e' | 'ne'
FLOAT ::= float (without exponent)
UFLOAT ::= float between 0 and 1 (without exponent)
INT ::= unsigned integer
ANAME ::= as for .net
QNAME ::= as for .net

Notes:
Node declarations must precede edge declarations.
The last declaration must be the netname declaration (h).
Empty lines and lines beginning with '#'are considered comments.
A '-' starting an eft or lft denotes an open interval end.
In any transition declaration, one must have `lft >= `eft or lft = 'w',
where `e denotes e if e>=0, or (-e)-1 otherwise
If eft = lft, then they may not be both negative (intervals may not be empty).
The letter 'K' (resp. 'M') following a weight or marking multiplies it by 10^3 (resp. 10^6).


Format .aut:
------------

It is the automaton description format of the Aldebaran tool (see the Aldebaran documents).


Format .adr:
------------

As .ndr above, except that trdesc and pldesc are replaced by the
following stdesc, and edgedesc is updated as follows:

stdesc ::= 's' <xpos> <ypos> <state> <anchor>
edgedesc ::= 'e' <state> <rad> <ang> <state> <rad> <ang> <label> <anchor>
state, label ::= ANAME | '{'QNAME'}'