Программа на языке qBasic игры «Жизнь»
DECLARE SUB Print1 ()
DECLARE SUB NewField ()
DECLARE SUB Send ()
DECLARE SUB Input1 ()
REM Игра Жизнь
DIM p AS INTEGER, m AS INTEGER
DIM SHARED a(0 TO 24, 0 TO 79) AS STRING * 1
DIM SHARED b(0 TO 24, 0 TO 79) AS STRING * 1
CLS
Input1
Print1
p = 1
WHILE p = 1
LOCATE 22, 5
PRINT "Показать следующую конфигурацию? (m=1 - да, иначе - нет)";
LOCATE 23, 5
INPUT "Введите m"; m
SLEEP 1
LOCATE 22, 5
PRINT SPC(73);
LOCATE 23, 5
PRINT SPC(73);
IF m = 1 THEN
NewField
Send
Print1
ELSE
p = 2
END IF
WEND
END
SUB Input1
DIM i AS INTEGER, j AS INTEGER, x AS INTEGER, y AS INTEGER
DIM t AS INTEGER
'начальная инициализация массивов A и B
FOR i = 0 TO 19
FOR j = 0 TO 79
a(i, j) = "-" : b(i, j) = "-"
NEXT j
NEXT i
'ввод начальной конфигурации (желательно начальную конфигурацию
t = 1 'популяций помещать в середину поля)
LOCATE 3, 15
PRINT "Вам предлагается ввести первоначальную конфигурацию."
LOCATE 4, 15
PRINT "Для этого необходимо ввести координаты каждой клетки,"
LOCATE 5, 23
PRINT " в которой есть жизнь."
LOCATE 6, 15
PRINT "Номер строки изменяется от 2 до 17"
LOCATE 7, 15
PRINT "Номер столбца изменяется от 2 до 77"
WHILE t = 1
LOCATE 20, 5
PRINT "Введите координаты клетки, в которой есть жизнь"
LOCATE 21, 5
INPUT "Введите номер строки"; y
LOCATE 22, 5
INPUT "Введите номер столбца"; x
a(y, x) = "*"
SLEEP 1
LOCATE 20, 5
PRINT SPC(73);
LOCATE 21, 5 : PRINT SPC(73);
LOCATE 22, 5 : PRINT SPC(73); : LOCATE 22, 5
PRINT "Будете вводить клетки в которых есть жизнь? (t=1 - да, иначе - нет)"
LOCATE 23, 5
INPUT "Введите t"; t
SLEEP 1
LOCATE 22, 5
PRINT SPC(73); : LOCATE 23, 5 : PRINT SPC(73);
WEND
END SUB
SUB NewField
DIM k AS INTEGER, i AS INTEGER, j AS INTEGER, t AS INTEGER
DIM d AS INTEGER
FOR i = 1 TO 18
FOR j = 1 TO 78
k = 0
FOR t = i - 1 TO i + 1
FOR d = j - 1 TO j + 1
IF a(t, d) = "*" THEN k = k + 1
NEXT d
NEXT t
IF a(i, j) = "*" THEN k = k - 1
IF k > 3 OR k < 2 THEN
b(i, j) = "-"
ELSEIF k = 3 THEN
b(i, j) = "*"
ELSE
b(i, j) = a(i, j)
END IF
NEXT j
NEXT i
END SUB
SUB Print1
DIM i AS INTEGER, j AS INTEGER
CLS
FOR i = 1 TO 18
FOR j = 1 TO 78
LOCATE i, j : PRINT a(i, j)
NEXT j
NEXT i
END SUB
SUB Send
DIM i AS INTEGER, j AS INTEGER
FOR i = 0 TO 19
FOR j = 0 TO 79
a(i, j) = b(i, j) : b(i, j) = "-"
NEXT j
NEXT i
END SUB
Глава 3. Отдельные вопросы методики преподавания учебного материала содержательной линии «Алгоритмизация и программирование»
«Нет, и не может быть, детей, которые бы не хотели трудиться. Неумение трудиться порождает нежелание, нежелание – лень. Главное средство предупреждения этих пороков – учить воспитанников самостоятельно трудиться»
В.А. Сухомлинский
Основной целью изучения предмета «Информатика и ИКТ» в общеобразовательных учреждениях является формирование информационной культуры у обучаемых. Под информационной культурой учащихся мы понимаем уровень развития личности, развитие алгоритмического, операционного типов мышления, способности личности к системному анализу и синтезу. Эти умения и навыки имеют общекультурную, общеобразовательную ценность, они нужны в современном информационном обществе каждому человеку, независимо от его профессиональной деятельности. Дальнейшее развитие школьного предмета «Информатика и ИКТ» мы видим в усилении внимания к общеобразовательным функциям этого курса, его возможностям для решения общих задач обучения, воспитания и развития школьников. Для достижения целей изучения предмета «Информатика и ИКТ», при рассмотрении методических аспектов изучения учебного материала содержательной линии «Алгоритмизация и программирование», желательно рассматривать со студентами, наряду с общепедагогическими технологиями обучения, предметные технологии обучения, такие как проектирование алгоритмов решения задач (проектирование алгоритмов «сверху вниз» и «снизу вверх»), имитационное моделирование исполнения программ компьютером, исполнителем этих программ и др.