Расширение возможностей имитационных экспериментов с моделями
Подпрограмма учета отказов оборудования.
Блоки типа gate, favail и funavail
Расчет работы производственного участка в детерминированном режиме достаточно просто может быть выполнен и обычными аналитическими методами. Наибольшую трудность представляет учет различного рода вероятностных событий. Таких, например, как наступление отказов оборудования и его последующее восстановление.
Простейшая подпрограмма ввода в модель отказов оборудования может быть построена на основе блоков favail и funavail – перевод устройства в недоступное состояние и обратно. Операнд «А» блока задает имя устройства. Так, например, если работа станка моделируется блоками seize, release с именем tst1, то перевод станка в недоступное для транзактов-деталей состояние производится блоком funavail с именем tst1.
Рис. 4.6. Блок-схема модели производственного модуля с учетом сбора готовых деталей в транспортные партии по 25 штук
Рис. 5.1. Блок-схема подпрограммы ввода отказов оборудования
Для наступления отказа оборудования необходимо, чтобы это оборудование работало. Соответствующая проверка производится блоком gate u . Блоки типа gate служат для проверки различных условий в модели. Например, gate u – проверка условия «устройство занято?». Проверка производится при попытке транзакта войти в блок gate . Основное правило для транзакта «условие не врет, проходи вперед». При не выполнении, транзакт задерживается в блоке gate .
Пример 3. Модель производственного модуля с отказами
оборудования
Промоделировать работу производственного модуля, если известно: интервал поступления партии заготовок составляет 2 ± 1 часа; число заготовок в партии – 10; время загрузки-выгрузки 25 ± 10 с; время обработки 6 ± 1 мин. Кроме этого известна статистика по отказам: отказ станка происходит через 8 ± 4 часа; его последующее восстановление длится 3 ± 2 часа. Программа выпуска – 500 штук. Необходимо определить время на выполнение заданной программы, оценить коэффициенты загрузки оборудования.
Основной сегмент модели остается таким же, как и в примере 2. Блок-схема подпрограммы ввода отказов оборудования представлена на рис. 5.1. Полный текст модели – на рис. 5.2. В тексте модели в данном случае отсутствует таймер, т.к. окончание моделирования происходит по выполнению заданной программы выпуска. Для этого используется блок terminate со счетчиком завершений (операнд «А» = 1). Число необходимых завершений задано картой start.
В результате моделирования получены следующие результаты.
Время выполнения производственной программы составило 115,5 часа. За счет простоев оборудования максимальное содержимое накопителя достигло 47 шт. На момент окончания модели в накопителе было 39 заготовок. Среднее время пролеживания 8022,85 с, коэффициент использования робота составил 5,9%, станка 62,8%.
Контроль качества и переналадка оборудования. Блоки transfer,
preempt и return
При расчете работы оборудования учитывается коэффициент брака, причем определенная часть брака может быть исправлена путем повторной обработки. Появление брака, как правило, вызвано неисправностью оборудования или необходимостью подналадки его. Устранение мелких неисправностей и подналадка выполняются оператором.
Рассмотрим несколько дополнительных блоков.
; GPSS/PC Program File TEST.GPS. (V 2, # 37349) 10-03-2002 11:18:46
10 *
20 * ЛАБОРАТОРНАЯ РАБОТА № 3
30 * ИССЛЕДОВАНИЕ РАБОТЫ ПРОИЗВОДСТВЕННОГО МОДУЛЯ
40 *
50 * ВЫПОЛНИЛ:...........
60 * ГРУППА:.............
70 * ПРИНЯЛ:.............
80 *
90 GENERATE 7200,3600 ;Ввод ДЕТАЛИ
100 SPLIT 9,BXP1 ;Разделение на заготовки
110 BXP1 LINK BXP1,FIFO,NEXT1 ;накопитель
120 NEXT1 SEIZE ZRM1 ;Занять робот
130 ADVANCE 25,10 ;Загрузка
140 SEIZE TST1 ;Занять станок
150 RELEASE ZRM1 ;Освободить робот
160 MET1 ADVANCE 360,60 ;Обработка ДЕТАЛИ
170 SEIZE ZRM1 ;Занять робот
180 RELEASE TST1 ;Освободить станок
190 ADVANCE 25,10 ;Выгрузка
200 UNLINK BXP1,NEXT1,1 ;Подготовить деталь
210 RELEASE ZRM1 ;Освободить робот
220 TERMINATE 1 ;Вывод из модели
230 *
240 * ВТОРОЙ СЕГМЕНТ МОДЕЛИ
250 * УЧЕТ ОТКАЗОВ ОБОРУДОВАНИЯ
260 *
270 GENERATE 28800,14400 ;ВВОД ОТКАЗА
280 GATE U TST1 ;ОБОРУДОВАНИЕ РАБОТАЕТ?
290 FUNAVAIL TST1 ;ВЫХОД ИЗ СТРОЯ
300 ADVANCE 10800,7200 ;ВОССТАНОВЛЕНИЕ
310 FAVAIL TST1 ;ПОВТОРНЫЙ ЗАПУСК
320 TERMINATE ;ВЫВОД ОТКАЗА ИЗ МОДЕЛИ
330 *
340 * CONTROL CARDS
350 *
360 START 500 ;СЧЕТЧИК ЗАВЕРШЕНИЯ
Рис. 5.2. Текст моделирующей программы
Блок transfer предназначен для изменения направления передачи транзактов. Обычно транзакты последовательно переходят из одного блока в другой. Для того, чтобы изменить эту последовательность и может быть использован блок transfer . Направления передачи транзактов задаются метками в операндах «В» и «С». Операнд «А» задает режим выбора следующего блока, к которому должен перейти транзакт.
Существуют следующие режимы работы блока transfer:
безусловный (,);
статистический (.);
BOTH.
Например: transfer .100,out1,brk1
10% всех входящих транзактов перейдет в блок с меткой brk1, остальные 90% – в блок с меткой out1.
Мы рассмотрели возможность занятия-освобождения одноканальных устройств – блоки seize, release . Возможность перевода устройств в недоступное состояние – блоки funavail и favail . Существует еще одна возможность воздействовать на моделируемое устройство.
Блоки preempt (захватить) и return (вернуть) – реализуют возможность прерывания обслуживания транзакта обслуживающим аппаратом.
Например: preempt tst1.
Транзакт, входящий в этот блок, «захватывает» устройство tst1, помещая транзакт-деталь, находившийся в этом устройстве, в цепочку прерываний. После выхода транзакта, захватившего обслуживающий аппарат, через блок return tst1, транзакт-деталь снова вернется на обработку.
Моделирование многоканальных устройств. Блоки enter и
leave
До сих пор мы рассматривали только одноканальные устройства. Однако, зачастую бывает необходимо промоделировать работу устройств, имеющих два и более каналов. Например, участок ЧПУ обслуживается несколькими операторами, причем, работа выполняется любым из них, свободным в этот момент. Для моделирования работы многоканальных устройств служит пара блоков enter (занять многоканальное устройство) и leave (освободить многоканальное устройство). Если между блоками seize , release может одновременно находится только один транзакт, (емкость устройства равна единице), то в многоканальном устройстве может присутствовать любое число транзактов, меньше или равное емкости устройства. Емкость устройства определяется картой storage , которая должна располагаться выше основного текста модели.
Пример 4. Модель производственного модуля с контролем
качества деталей и переналадкой оборудования
Построить модель производственного модуля. Время поступления партий 60 ± 30 мин., число деталей в партии – 50; время загрузки-выгрузки 10 ± 5 с, время обработки 60 ± 5 с. Дополнительно известно, что процент брака достигает 10%, причем 30% – брак исправимый. Время переналадки оборудования составляет 4 ± 2 мин.
Необходимо промоделировать работу модуля в течение 8 часов, оценить возможность выполнения заданной программы, коэффициенты загрузки оборудования и коэффициент занятости оператора.
Блок-схема алгоритма модели приведена на рис. 5.3.
Рис. 5.3. Блок-схема алгоритма модели
После выполнения подпрограммы моделирования работы модуля необходимо осуществить контроль наличия брака. Процент контроля моделируется использованием блока transfer с операндом «А», равным .100. Данный блок случайным образом будет отсеивать 10% транзактов и направлять их на подпрограмму «переналадка» по метке brk1. Остальные 90% деталей по метке out1 переходят в блок terminate, служащий счетчиком готовых деталей. Отбракованный транзакт-деталь попадает в блок preempt, вызывая захват станка. После этого выполняется попытка занять оператора в блоке enter и, если это удается, моделируется задержка на восстановление станка. После задержки моделируется событие повторного запуска, (блок return) и освобождение оператора. Теперь необходимо решить, как поступить с бракованной деталью. В очередном блоке transfer 30% транзактов возвращаются во входной накопитель (метка bxp1), остальные выводятся из модели вторым блоком terminate, являющимся счетчиком брака.
Распечатка модели приведена на рис. 5.4.
; GPSS/PC Program File TEST.GPS. (V 2, # 37349) 10-03-2002 11:18:46
10 *
20 OPR STORAGE 1 ;ОПРЕДЕЛЕНИЕ ЧИСЛА ОПЕРАТОРОВ
30 *
40 GENERATE 3600,1800 ;Ввод ДЕТАЛЕЙ
50 SPLIT 49,BXP1 ;Разделение на заготовки
60 BXP1 LINK BXP1,FIFO,NEXT1 ;накопитель
70 NEXT1 SEIZE ZRM1 ;Занять робот
80 ADVANCE 10,5 ;Загрузка
90 SEIZE TST1 ;Занять станок
100 RELEASE ZRM1 ;Освободить робот
110 ADVANCE 60,5 ;Обработка ДЕТАЛИ
120 SEIZE ZRM1 ;Занять робот
130 RELEASE TST1 ;Освободить станок
140 ADVANCE 10,5 ;Выгрузка
150 UNLINK BXP1,NEXT1,1 ;Подготовить деталь
160 RELEASE ZRM1 ;Освободить робот
170 TRANSFER .100,OUT1,BRK1 ;Контроль брака
180 BRK1 PREEMPT TST1 ;Останов станка
190 ENTER OPR ;Занять оператора
200 ADVANCE 240,120 ;Переналадка
210 RETURN TST1 ;ЗАПУСК СТАНКА
220 LEAVE OPR ;Освободить оператора
230 TRANSFER .300,BRAK,BXP1 ;Брак исправимый?
240 BRAK TERMINATE ;Счетчик брака
250 OUT1 TERMINATE ;Счетчик готовых деталей
260 *
270 * ВТОРОЙ СЕГМЕНТ МОДЕЛИ
280 * ТАЙМЕР
290 *
300 GENERATE 28800 ;ЗАВЕРШЕНИЕ МОДЕЛИРОВАНИЯ
310 TERMINATE 1 ;ЧЕРЕЗ 8 ЧАСОВ
320 *
330 * CONTROL CARDS
340 *
350 START 1 ;1 ПРОГОН МОДЕЛИ
Рис. 5.4. Текст моделирующей программы
В ходе моделирования получены следующие результаты: среднее время пролеживания детали составило 6219 с., максимальная длина очереди выросла до 118 штук. Всего было обработано 231 деталь, из них 211 годных и 20 штук – неисправимый брак. На повторную обработку было возвращено 6 деталей. Коэффициент загрузки оператора составил 19,9%.
В данном примере контроль брака производился без временной задержки деталей и участия оператора. Однако автоматизированные системы контроля распространены еще крайне мало. На рис. 5.5 приведена блок-схема модели с контролем качества готовых деталей оператором.
Рис. 5.5. Блок-схема алгоритма модели с контролем качества готовых
деталей оператором
Транзакт-деталь после прохождения стадии обработки присоединяется к очереди на контроль (блок queue). Если оператор свободен, моделируются события «занять оператора» и «выход из очереди». По окончании задержки транзакта на время контроля качества детали, моделируется событие «освобождение оператора». Далее транзакт переходит к уже рассмотренной подпрограмме контроля. Распечатка текста модели приведена на рис. 5.6.
; GPSS/PC Program File TEST.GPS. (V 2, # 37349) 10-03-2002 11:18:46
10 *
20 OPR STORAGE 1 ;ЧИСЛО ОПЕРАТОРОВ
30 *
40 GENERATE 3600,1800 ;Ввод ДЕТАЛЕЙ
50 SPLIT 49,BXP1 ;Разделение на заготовки
60 BXP1 LINK BXP1,FIFO,NEXT1 ;накопитель
70 NEXT1 SEIZE ZRM1 ;Занять робот
80 ADVANCE 10,5 ;Загрузка
90 SEIZE TST1 ;Занять станок
100 RELEASE ZRM1 ;Освободить робот
110 ADVANCE 60,5 ;Обработка ДЕТАЛИ
120 SEIZE ZRM1 ;Занять робот
130 RELEASE TST1 ;Освободить станок
140 ADVANCE 10,5 ;Выгрузка
150 UNLINK BXP1,NEXT1,1 ;Подготовить деталь
160 RELEASE ZRM1 ;Освободить робот
170 QUEUE OPRT ;ОЧЕРЕДЬ НА КОНТРОЛЬ
180 ENTER OPR ;Занять оператора
190 DEPART OPRT ;ВЫХОД ИЗ ОЧЕРЕДИ
200 ADVANCE 10,5 ;КОНТРОЛЬ ДЕТАЛИ
210 LEAVE OPR ;Освободить оператора
220 TRANSFER .100,OUT1,BRK1 ;Контроль брака
230 BRK1 PREEMPT TST1 ;Останов станка
240 ENTER OPR ;Занять оператора
250 ADVANCE 240,120 ;Переналадка
260 RETURN TST1 ;ЗАПУСК СТАНКА
270 LEAVE OPR ;Освободить оператора
280 TRANSFER .300,BRAK,BXP1 ;Брак исправимый?
290 BRAK TERMINATE ;Счетчик брака
300 OUT1 TERMINATE ;Счетчик готовых деталей
310 *
320 * ВТОРОЙ СЕГМЕНТ МОДЕЛИ
330 * ТАЙМЕР
340 *
350 GENERATE 28800 ;ЗАВЕРШЕНИЕ МОДЕЛИРОВАНИЯ
360 TERMINATE 1 ;ЧЕРЕЗ 8 ЧАСОВ
370 *
380 * CONTROL CARDS
390 *
400 START 1 ;1 ПРОГОН МОДЕЛИ
Рис. 5.6. Текст моделирующей программы
Пример 5. Модель производственного участка
До сих пор моделировалась работа отдельных производственных модулей. Представляет интерес рассмотреть принципы объединения отдельных подпрограмм модели. Для этого обратимся к следующему примеру.
Требуется промоделировать работу 3-х производственных модулей, работающих параллельно, если известно: интервал поступления заготовок по всем модулям составляет 80 ± 30 с; среднее время загрузки – 10 ± 5 с; среднее время обработки – 60 ± 10 с. Bee три модуля обслуживаются одним транспортным роботом, который выполняет операции выгрузки и транспортировки готовых деталей. Совмещенное время выгрузки-транспортировки составляет 40 ± 10 с. Исследовать возможность установления транспортному роботу различных приоритетов в обслуживании модулей.
Блок-схема модели приведена на рис. 5.7. Ввод транзактов-заготовок по всем модулям производится блоками generate 80,30, далее моделируются события занятия загрузочного робота, загрузка, занятие станка, освобождение робота и задержка транзактов на время обработки. По окончанию обработки все транзакты-детали пытаются занять транспортный робот. Для транзакта, которому это удалось сделать, моделируются события освобождения станка, транспортировки, освобождения транспортного робота. Остальные транзакты ожидают своей очереди на обслуживание.
Как уже говорилось, обычно, транзакты последовательно переходят от одного блока к другому. В данном случае последовательная цепочка может быть ориентирована только для одного сегмента модели. Поэтому необходимо организовать объединение сегментов после моделирования события освобождения станка. Для этой цели в первый сегмент введен «пустой» блок advance с меткой all1. В двух других использован блок transfer с безусловным режимом перехода по метке (опущен операнд «А»).
После объединения потоков в блоке advance , транзакты попадают в блок priority, который выравнивает их приоритеты для моделирования последующих событий. Текст модели приведен на рис. 5.8.
Первый прогон модели осуществляется без установления приоритетов в обслуживании.
Для второго прогона в блоке generate первого сегмента установлен более высокий приоритет создаваемых транзактов. Теперь транспортный робот в первую очередь будет обслуживать первый модуль.
Для третьего прогона еще более высокий приоритет установлен транзактом третьего обрабатывающего модуля.
Основные результаты моделирования сведены в таблицу 5.1.
Рис. 5.7. Блок-схема модели
; GPSS/PC Program File TEST.GPS. (V 2, # 37349) 10-03-2002 11:18:46
10 *
20 * 1 СЕГМЕНТ МОДЕЛИ
30 *
40 MET1 GENERATE 80,30 ;Ввод заготовки
50 SEIZE ZRM1 ;Занять робот
60 ADVANCE 10,5 ;Загрузка
70 SEIZE TST1 ;Занять станок
80 RELEASE ZRM1 ;Освободить робот
90 ADVANCE 60,10 ;Обработка заготовки
100 SEIZE TRM ;Занять транспортный робот
110 RELEASE TST1 ;Освободить станок
120 ALL1 ADVANCE ;ОБЪЕДИНЕНИЕ ПОТОКОВ
130 PRIORITY 0
140 ADVANCE 40,10 ;ВЫГРУЗКА
150 RELEASE TRM ;Освободить транспортный робот
160 TERMINATE ;Вывод из модели
170 *
180 * ВВОД ДЕТАЛЕЙ СО ВТОРОГО МОДУЛЯ
190 *
200 GENERATE 80,30 ;Ввод заготовки
210 SEIZE ZRM2 ;Занять робот
220 ADVANCE 10,5 ;Загрузка
230 SEIZE TST2 ;Занять станок
240 RELEASE ZRM2 ;Освободить робот
250 ADVANCE 60,10 ;Обработка заготовки
260 SEIZE TRM ;Занять транспортный робот
270 RELEASE TST2 ;Освободить станок
280 TRANSFER ,ALL1 ;ОБЪЕДИНЕНИЕ ПОТОКОВ
290 *
300 * ВВОД ДЕТАЛЕЙ С ТРЕТЬЕГО МОДУЛЯ
310 *
320 MET2 GENERATE 80,30 ;Ввод заготовки
330 SEIZE ZRM3 ;Занять робот
340 ADVANCE 10,5 ;Загрузка
350 SEIZE TST3 ;Занять станок
360 RELEASE ZRM3 ;Освободить робот
370 ADVANCE 60,10 ;Обработка заготовки
380 SEIZE TRM ;Занять транспортный робот
390 RELEASE TST3 ;Освободить станок
400 TRANSFER ,ALL1 ;ОБЪЕДИНЕНИЕ ПОТОКОВ
410 *
420 * 2 СЕГМЕНТ МОДЕЛИ
430 *
440 GENERATE 3600
450 TERMINATE 1 ;1 ЧАС
460 *
470 START 1
480 MET1 GENERATE 80,30,,,2
490 CLEAR
500 START 1
510 MET2 GENERATE 80,30,,,3
520 CLEAR
530 START 1
Рис. 5.8. Текст моделирующей программы
Таблица 5.1
№№ прогона |
Число обработанных деталей (шт.) |
Коэффициент загрузки % |
|||||
М1 |
М2 |
М3 |
Станок 1 |
Станок 2 |
Станок 3 |
Транспортный робот |
|
1 |
29 |
28 |
29 |
97,1 |
97,0 |
96,3 |
95,9 |
2 |
41 |
21 |
22 |
93,8 |
97,0 |
96,3 |
95,8 |
3 |
42 |
4 |
42 |
96,5 |
97,0 |
93,0 |
95,9 |
В данном примере все три станка, объединенные транспортным роботом, были задействованы на изготовление деталей одного типа.
Пример 6. Модель РТК
Рассмотрим вариант построения модели робототехнологического комплекса (РТК), состоящего из 3-х производственных модулей, объединенных транспортным роботом. Заготовки на все три станка поступают поштучно, с интервалами, определяемыми предыдущими операциями. Загрузка производится загрузочными роботами, выгрузка и транспортировка готовых деталей на склад осуществляется общим транспортным роботом. Очередная заготовка может поступить на обработку при условии, что предыдущая обработана и покинула модуль.
Детали первого, второго и третьего типа поступают соответственно на первый, второй и третий модули с интервалами 100 ± 50 с; 250 ± 60 с; 300 ± 120 с. Время загрузки одинаково и составляет 10 ± 5 с. Время обработки соответственно 90 ± 10 с, 180 ± 60 с, 250 ± 50 с.
Транспортный робот отвозит готовые детали на склад. Время транспортировки составляет 40 ± 10 с, 60 ± 20 с, 90 ± 30 с. соответственно с первого, второго и третьего модуля.
Поскольку расстояние до склада и время транспортировки различно, необходимо решить вопрос размещения заказанных типов деталей по обрабатывающим модулям, а также исследовать возможность установления более высоких приоритетов обслуживания деталям первого и второго типов.
Блок-схема алгоритма модели приведена на рис. 5.9, а текст моделирующей программы - на рис. 5.10. Все три сегмента моделирующие работу оборудования имеют одинаковую структуру. Различия введены лишь в символические имена и числовые значения операндов блоков. Поскольку время транспортирования для всех модулей различно и необходим сбор статистики по всем видам деталей, объединение потоков транзактов в модели не производится.
Рис. 5.9. Блок-схема алгоритма модели
; GPSS/PC Program File TEST.GPS. (V 2, # 37349) 10-03-2002 11:18:46
10 *
20 * РАБОТА ПЕРВОГО МОДУЛЯ
30 *
40 MET1 GENERATE 100,50 ;Ввод заготовки
50 SEIZE ZRM1 ;Занять робот
60 ADVANCE 10,5 ;Загрузка
70 SEIZE TST1 ;Занять станок
80 RELEASE ZRM1 ;Освободить робот
90 ADVANCE 90,10 ;Обработка заготовки
100 SEIZE TRM ;Занять транспортный робот
110 RELEASE TST1 ;Освободить станок
120 ADVANCE 40,10 ;ТРАНСПОРТИРОВКА
130 RELEASE TRM ;Освободить транспортный робот
140 TERMINATE ;СЧЕТЧИК 1
150 *
160 * РАБОТА ВТОРОГО МОДУЛЯ
170 *
180 MET2 GENERATE 250,60 ;Ввод заготовки
190 SEIZE ZRM2 ;Занять робот
200 ADVANCE 10,5 ;Загрузка
210 SEIZE TST2 ;Занять станок
220 RELEASE ZRM2 ;Освободить робот
230 ADVANCE 180,60 ;Обработка заготовки
240 SEIZE TRM ;Занять транспортный робот
250 RELEASE TST2 ;Освободить станок
260 ADVANCE 60,20 ;ТРАНСПОРТИРОВКА
270 RELEASE TRM ;Освободить транспортный робот
280 TERMINATE ;СЧЕТЧИК 2
290 *
300 * РАБОТА ТРЕТЬЕГО МОДУЛЯ
310 *
320 GENERATE 300,120 ;Ввод заготовки
330 SEIZE ZRM3 ;Занять робот
340 ADVANCE 10,5 ;Загрузка
350 SEIZE TST3 ;Занять станок
360 RELEASE ZRM3 ;Освободить робот
370 ADVANCE 250,60 ;Обработка заготовки
380 SEIZE TRM ;Занять транспортный робот
390 RELEASE TST3 ;Освободить станок
400 ADVANCE 90,30 ;ТРАНСПОРТИРОВКА
410 RELEASE TRM ;Освободить транспортный робот
420 TERMINATE ;СЧЕТЧИК 3
430 *
440 * 2 СЕГМЕНТ МОДЕЛИ
450 *
460 GENERATE 28800 ;ВРЕМЯ МОДЕЛИРОВАНИЯ
470 TERMINATE 1 ;8 ЧАСОВ
480 *
490 START 1
500 MET1 GENERATE 100,50,,,3
510 CLEAR
520 START 1
530 MET2 GENERATE 250,60,,,2
540 CLEAR
550 START 1
Рис. 5.10. Текст моделирующей программы
После событий занятие транспортного робота и освобождения соответствующего станка для всех сегментов моделируется задержка на время транспортировки, освобождения робота и вывод из модуля.
Блоки terminate и в данном случае используются в качестве счетчиков готовых деталей.
Управляющие карты соответствуют варианту исследования влияния приоритетов на работу моделируемых объектов.
Результаты моделирования сведены в таблицу 5.2.
Таблица 5.2
№№ прогона |
Число обработанных деталей (шт.) |
Коэффициент загрузки % |
|||||
М1 |
М2 |
М3 |
Станок 1 |
Станок 2 |
Станок 3 |
Транспортный робот |
|
1 |
206 |
106 |
92 |
99,4 |
97,3 |
98,5 |
97,6 |
2 |
210 |
112 |
92 |
99,4 |
81,6 |
98,2 |
92,3 |
3 |
229 |
115 |
94 |
99,4 |
87,0 |
87,1 |
83,8 |
4 |
243 |
116 |
95 |
99,4 |
90,7 |
91,5 |
89,1 |
5 |
240 |
115 |
95 |
99,4 |
86,4 |
97,2 |
86,3 |
Прогоны 1–3 относятся к размещению деталей по модулям. Прогоны 4–5 – установлению приоритетов. Причем, для исследования приоритетов за основу был взят 3-й вариант размещения заказов по станкам.
Как видно из таблицы 5.2 рациональное размещение заказов (наиболее короткая операция должна быть ближе к складу) позволяет увеличить выход готовой продукции. Использование более высокого приоритета для конкретных операций обработки также позволило значительно увеличить выход готовой продукции за счет упорядочения работы транспортного робота.