2.2.3. Необходимые входные файлы для моделирования.

*XOR Gate ver1

*Propagation Delay, Transition Time

* HSPICE Netlist

.options POST=1 parhier=local

* Models section

* Include models

.include '/student_lab/digital_ic/all_models/model_val'

* Design variables section

* Define parameters

.param vdd = VDD_val

.param tr=TR_val

.param freq=FREQ_val

.param per=’1/freq’

.param tst=’0.5*per’

.temp Temp_val

* Structural netlist section

.include '/student_lab/digital_ic/variant_val/xor02_1.netl'

vvss vss gnd dc=0

vvdd vdd gnd dc='vdd'

***Input Signals

vina1 ina a pulse (0 vdd 'tst+0.0*per' tr tr 'per-tr' '4.0*per')

vina2 a 0 pulse (0 vdd 'tst+2.5*per' tr tr 'per-tr' '4.0*per')

vinb1 inb b pulse (0 vdd 'tst+0.5*per' tr tr 'per-tr' '4.0*per')

vinb2 b 0 pulse (0 vdd 'tst+2.0*per' tr tr 'per-tr' '4.0*per')

cload z gnd LOAD_val

* Analysis section

* Transient Analyses

.tran ‘0.01*tr’ ‘5*per’

.probe v(*)

*Options

.option post probe

.option autostop

***Measures

***Propagation Delay

.meas tran tplh_ina_z_1 trig v(ina) val='vdd*0.5' rise=1 targ v(z) val='vdd*0.5' rise=1

.meas tran tphl_ina_z_1 trig v(ina) val='vdd*0.5' fall=2 targ v(z) val='vdd*0.5' fall=4

.meas tran tplh_ina_z_2 trig v(ina) val='vdd*0.5' fall=1 targ v(z) val='vdd*0.5' rise=2

.meas tran tphl_ina_z_2 trig v(ina) val='vdd*0.5' rise=2 targ v(z) val='vdd*0.5' fall=3

.meas tran tplh_inb_z_1 trig v(inb) val='vdd*0.5' fall=2 targ v(z) val='vdd*0.5' rise=4

.meas tran tphl_inb_z_1 trig v(inb) val='vdd*0.5' rise=1 targ v(z) val='vdd*0.5' fall=1

.meas tran tplh_inb_z_2 trig v(inb) val='vdd*0.5' rise=2 targ v(z) val='vdd*0.5' rise=3

.meas tran tphl_inb_z_2 trig v(inb) val='vdd*0.5' fall=1 targ v(z) val='vdd*0.5' fall=2

***Transition Time

.meas tran ttrlh_ina_z_1 trig v(z) val='0.1*vdd' rise=1 targ v(z) val='0.9*vdd' rise=1

.meas tran ttrhl_ina_z_1 trig v(z) val='0.9*vdd' fall=4 targ v(z) val='0.1*vdd' fall=4

.meas tran ttrlh_ina_z_2 trig v(z) val='0.1*vdd' rise=2 targ v(z) val='0.9*vdd' rise=2

.meas tran ttrhl_ina_z_2 trig v(z) val='0.9*vdd' fall=3 targ v(z) val='0.1*vdd' fall=3

.meas tran ttrlh_inb_z_1 trig v(z) val='0.1*vdd' rise=4 targ v(z) val='0.9*vdd' rise=4

.meas tran ttrhl_inb_z_1 trig v(z) val='0.9*vdd' fall=1 targ v(z) val='0.1*vdd' fall=1

.meas tran ttrlh_inb_z_2 trig v(z) val='0.1*vdd' rise=3 targ v(z) val='0.9*vdd' rise=3

.meas tran ttrhl_inb_z_2 trig v(z) val='0.9*vdd' fall=2 targ v(z) val='0.1*vdd' fall=2

.end