Графики зависимости поверхностного сопротивления от корня времени разгонки с разными значениями энергии.

График зависимости глубины p-n-перехода от квадрата времени разгонки с разными значениями энергии.

По полученным графиком можно сделать вывод, о то что с увеличением времени термического отжига растёт глубина p-n перехода, а так же увеличивается угол наклона в зависимости от дозы, т.е. чем больше доза тем больше угол наклона и соответственно глубина p-n перехода.

Так же с увеличением времени термического отжига уменьшается Rs, такое явление происходит в результате проникновения большего количества ионов в подложку.

ЧАСТЬ B.

Листинг sprocess_fps.cmd для задание B:

graphics off //Деактивировать графический режим

implant tables=Default //задаём таблицу с параметрами распределения для различных видов

// примесей, доз, энергий и т.д.

pdbSet Silicon Dopant DiffModel Pair //Задаём модель диффузии

#Задаём область моделирования минимальный шаг 1 нм, максимыльный 50 нм, отношение размеров соседних ячеек 1,2

mgoals on min.normal.size=1<nm> max.lateral.size=50<nm> normal.growth.ratio=1.2 accuracy=0.1<nm>

#Инициализируем сетку

line x loc=0 tag=Top spacing=0.05

line x loc=2 tag=Bottom spacing=0.05

line y loc=0 tag=Mid spacing=0.05

line y loc=@<Lg*0.001/2+0.3>@ tag=Right spacing=0.05

#Формируем фосфорную подложку с концетрацией и ориентацией (100)

region Silicon xlo=Top xhi=Bottom ylo=Mid yhi=Right

init field=Phosphorus concentration=5.00e14 wafer.orient=100 slice.angle=-90

struct smesh=n@node@_0 #Сохраняем структуру

#Осаждаем оксидную плёнку толщиной 20 нм анизотропным способом

deposit Oxide thickness=20<nm> type=anisotropic

struct smesh=n@node@_1 #Сохраняем структуру

#Имплантация Бором с разными концентрациями и энергией, под углом 0 ^о

implant Boron dose=2.00e13 energy=120 tilt=0 rotation=0

implant Boron dose=1.00e13 energy=50 tilt=0 rotation=0

implant Boron dose=1.00e13 energy=25 tilt=0 rotation=0

#Выполняем диффузию при T=1050®C в течение 10 сек

diffuse time=10<s> temp=1050

struct smesh=n@node@_3 //Сохраняем структуру

#Травим оксидную плёнку толщиной 22 нм

etch Oxide thickness=22<nm> type=anisotropic

struct smesh=n@node@_4 //Сохраняем структуру

#Окисление затвора

deposit Oxide thickness=1.2<nm> type=anisotropic

struct smesh=n@node@_5 //Сохраняем структуру

#Осаждение полизатвор

deposit PolySilicon thickness=0.14 type=anisotropic

mask name=gate_mask left=-1 right=@<Lg*0.001/2>@

etch Poly thickness=0.16 mask=gate_mask type=anisotropic

etch Oxide thickness=0.1 type=anisotropic

struct smesh=n@node@_6 //Сохранить структуру

#Описание окисляющей атмосферы

gas_flow name=flow_1 flowN2=0.99 flowO2=0.01

diffuse time=10 temp=900 gas_flow=flow_1

struct smesh=n@node@_7 //Сохранить структуру

#Отражение перед Halo

transform reflect left

struct smesh=n@node@_8 //Сохранить структуру

#N-LDD имплантация

implant Arsenic dose=8.00e14 energy=5 tilt=0 rotation=0 ifactor=0.1

#HALO имплантация

implant Boron dose=6.00e13 energy=10 tilt=30 rotation=0 mult.rot=4 ifactor=0.1

#Обрезаем структуру

transform cut left loc=0

struct smesh=n@node@_11 //Сохранить структуру

#Диффузия LDD/HALO имплантации

diffuse time=1<s> temp=1000 init=1e-8

struct smesh=n@node@_12 //Сохранить структуру

#Нитридные спейсеры

deposit Oxide thickness=0.01 type=isotropic

deposit Nitride thickness=0.025 type=isotropic

deposit Oxide thickness=0.01 type=isotropic

etch Oxide thickness=0.05 type=anisotropic

etch Oxide thickness=0.001 type=isotropic

etch Nitride thickness=0.06 type=anisotropic

etch Nitride thickness=0.001 type=isotropic

etch Oxide thickness=0.008 type=anisotropic

struct smesh=n@node@_13 //Сохранить структуру

#N+ имплантация

implant spec=Phosphorus damage

implant Phosphorus dose=1.50e15 energy=20 tilt=0 rotation=0 ifactor=0.1

#Конечная диффузия

diffuse time=1<s> temp=1025 init=1e-8

struct smesh=n@node@_15 //Сохранить структуру

# 16a) ----- #split <Strain> --------------------------------------------------

etch Oxide thickness=30<nm> type=isotropic

deposit Oxynitride thickness=@CapLr@<nm> type=isotropic

struct smesh=n@node@_16a //Сохранить структуру

#Напряжение Оксинитрида

stress Oxynitride sxxi=@Sxx@e9<Pa> syyi=@Syy@e9<Pa> szzi=@Szz@e9<Pa>

struct smesh=n@node@_16b //Сохранить структуру

#Пересчитаем распределение напряжение

diffuse time=1e-10 temp=1025

#Последнее отражение

transform reflect left

struct smesh=n@node@_17 //Сохранить структуру

#Сохранить профиль легирования

SetPlxList { NetActive }

WritePlx n@node@_CH y=0

WritePlx n@node@_SD y=@<Lg*0.001/2+0.295>@

#Считаем Rs

SheetResistance y=0

SheetResistance y=@<Lg*0.001/2+0.295>@

Exit

Новые изученные команды

Команда	Описание
gas_flow	Задаёт парциальное давление газа
mask	Применяется когда нужно определить область на которую будет какое-либо воздействие
implant tables=Default	Задаёт таблицу с параметрами распределения для различных видов примесей, доз, энергий и т.д.
pdbSet Silicon Dopant DiffModel	Задаёт модель диффузии

Распределение легирующей примеси на различных стадиях технологического маршрута для толщины затвора 50 нм