Примеры использования

awk может использоваться непредсказуемым способом: системы баз данных, различные компиляторы и трасляторы, в дополнение к традиционным задачам поиска информации, обработки данных и генерации отчетов. Программы awk значительно короче, чем аналогичные программы, написанные на традиционных языках программирования, таких как Pascal и Си. В этом подразделе приведены примеры, иллюстрирующие некоторые дополнительные возможности программ awk.

Генерирование отчетов

awk особенно успешно применяется для выдачи отчетов, которые суммируют и форматируют информацию. Предположим, вы хотите создать отчет из файла countries, в котором континенты перечисляются в алфавитном порядке и по каждому континенту страны перечисляются в убывающем по населению порядку:

Africa:

Sudan 19

Algeria 18

Asia:

China 866

India 637

USSR 262

Australia:

Australia 14

North America:

USA 219

Canada 24

South America:

Brazil 116

Argentina 26

Так как здесь несколько задач обработки данных, то намного легче выполнить этот отчет в несколько стадий. Первая: создать список троек "континент_страна_население", в котором каждое поле отделяется запятой. Это можно сделать с помощью следующей программы triplies, которая использует массив pop, индексированный в форме "континент_страна" для сохранения количества населения данной страны. Оператор print в секции END этой программы создает список троек "континент-страна-население", который направляется в программу sort:

BEGIN { FS = "\t" }

{ pop[$4 ":" $1] += $3 }

END { for ( cc in pop )

print cc "":" pop[cc] | "sort -t: +0 -1 +2nr" }

Аргумент для sort заслуживает специального внимания. Аргумент -t: говорит sort, чтобы использовать ":" как разделитель полей. Аргументы +0 и -1 делают первое поле первичным ключом sort. В общем случае +i -j делают поля i+1, i+2, ... j ключом сортировки. Если j опущено, поля от i+1 до конца записи используются. Аргумент +2nr делает третье поле (цифровое уменьшение) вторичным ключом sort ( n - числовое, r - обратный порядок). Относительно файла countries эта программа выдает результат:

Africa:Sudan:19

Africa:Algeria:18

Asia:China:866

Asia:India:637

Asia:USSR:262

Australia:Australia:14

North America:USA:219

North America:Canada:24

South America:Brazil:116

South America:Argentina:26

Порядок вывода правильный, но неверен формат. Чтобы преобразовать формат вывода в требуемую форму, запустите программу format с этими данными:

BEGIN { FS = ":" }

{ if ($1 != prev) {

print "\n" $1 ":"

prev = $1

}

printf "\t%-10s %6d\n", $2, $3

}

Эта программа прерывания управления печатает только первое появление имени континента и форматирует строки "страна-население", соответствующие этому континенту, требуемым способом. Командная строка:

awk -f triplies countries | awk -f format

дает требуемый отчет. В этом примере предполагается, что сложные задачи преобразования данных и их форматирования могут быть сокращены до нескольких простых команд awk и сортировки.