Задачи для самостоятельного решения

1. Для некоторого вектора произвольной длины найти максимум, минимум и значение, наиболее близкое к среднему.

2. Для некоторой двумерной матрицы A найдите определитель D(A)=a₁₁a₂₂-a₂₁a₁₂

3. В одномерном массиве переставьте первый и последний элементы местами.

4. Напишите программу, которая по заданному натуральному числу n находит наименьший элемент массива B[0,n-1].

5. Напишите программу, которая по заданному натуральному числу n находит индекс заданного элемента массива B[0,n-1].

6. Замените минимальный элемент массива А[1..5] его удвоенным индексом.

7. Осуществите циклическую перестановку элементов массива: первый элемент должен стать вторым, второй - третьим и т.д., последний - первым. Нового массива не заводить.

8. Напишите программу, увеличивающую на 2 все элементы массива Y[1..n], которые больше 10.

9. Переставьте элементы одномерного массива в обратном порядке.

10. Напишите программу, которая по заданному натуральному числу n вычисляет сумму элементов массива B[0,n-1].

11. Для целого массива A[1..n] найдите сумму всех: (а) положительных элементов; (б) отрицательных; (в) ненулевых элементов.

12. Вычислите произведение сумм положительных и отрицательных элементов массива A[1..5].

13. В данной последовательности целых чисел найдите количество различных чётных чисел.

14. Напишите программу замены отрицательных элементов массива Y[1..n] их квадратами.

15. Напишите программу замены положительных элементов массива Y[1..n] на 0.

Лабораторная работа №9. Цепочки

Вопросы, необходимые рассмотреть при подготовке к лабораторной работе:

1. Понятие "цепочечная команда"

2. Синтаксис цепочечных команд

3. Пересылка цепочки

4. Сравнение цепочек 

5. Сканирование цепочки 

6. Загрузка элемента из цепочки 

7. Сохранение элемента в цепочке

8. Префиксы повторения

9. Цепочечные индексные регистры

10. Направление обработки цепочки

Демонстрационные примеры.

 Пример1. Демонстрация перемещения цепочки-источника в цепочку-приёмник командой MOVS

MASM

MODEL small

.STACK 256

.DATA ; Сегмент данных

source DB "Тестируемая строка",'$' ; Строка-источник

dest DB 19 DUP (" ") ; Строка-приёмник

.CODE

ASSUME ds:@data, es:@data

Main: ; Точка входа в программу

mov ax,@data ; Загрузка сегментных регистров

mov ds,ax ; Настройка регистров ds и es

mov es,ax ; на адрес сегмента данных

cld ; Сброс флага DF - обработка

; строки от начала к концу

; строки-приёмника

lea si,source ; Загрузка в si смещения

; строки-источника

lea di,dest ; Загрузка в DS смещения

mov cx,20 ; Счётчик повторений (длина

; строки) для префикса rep

rep movs dest,source ; Пересылка строки

lea dx,dest

mov ah,09h ; Вывод на экран

int 21h ; строки-приёмника

mov ah,08h ; Функция ожидания нажатия любой клавиши

int 21h ; Вызов DOS: код нажатой клавиши - в AL

Exit:

mov ax,4C00h

int 21h

END Main

Пример 2. Демонстрация использования команды CMPS для сравнения двух строк, заданных в программе

IDEAL

MODEL small

STACK 256

DATASEG

match DB 'Строки совпадают','$'

failed DB 'Строки не совпадают, так как: ','$'

str1 DB "0123456789",0ah,0dh,'$' ; Исследуемые строки

str2 DB "0143406779",0ah,0dh,'$' ;

; --------------------------------------------------------

; После просмотра результата программы при исходных данных

; закомментируйте предыдущую строку и уберите знак

; комментария со следующей строки

; --------------------------------

; str2 DB "0123456789",0ah,0dh,'$'

CODESEG

ASSUME ds:@data, es:@data; Привязка DS и ES к сегменту данных

Main:

mov ax,@data ; Загрузка сегментных регистров

mov ds,ax

mov es,ax ; Настройка ES на DS

; --------

mov ah,09h ; Функция для вывода строки

lea dx,[str1] ; Загрузка адреса строки в регистр DX

int 21h ; Вызов функции для вывода строки

lea dx,[str2] ; Загрузка адреса строки в регистр DX

int 21h ; Вызов функции для вывода строки

cld ; Сброс флага DF для осуществления сравнения

; строк в направлении возрастания адресов

lea si,[str1] ; Загрузка в SI смещения строки str1

lea di,[str2] ; Загрузка в DI смещения строки str2

mov cx,10 ; Длина исследуемых строк

; -------------------------------------------------------

; Сравнение строк до тех пор, пока сравниваемые элементы

; строк равны. Выход при обнаружении несовпавшего элемента

; -------------------------------------------------------

mov ax,0 ; Для указания того факта, что строки равны

Cycl:

repe cmps [str1],[str2]

jcxz Equal ; Переход, если закончен просмотр строк

jne Not_match ; Переход, если строки не совпадают

Equal:

cmp ax,1

je Exit ; Переход, если было несовпадение в строках

mov ah,09h

lea dx,[match]

int 21h ; Вывод сообщения о том, что строки равны

jmp Exit

Not_match:

cmp ax,1 ; Если обнаружено больше одного несовпадения,

je See ; то не печатать повтор сообщения об этом

mov ah,09h

lea dx,[failed]

int 21h ; Вывод сообщения о том, что строки не равны

See:

dec si ; Возврат к несовпавшему элементу в строке

dec di ;

; --------

mov ah,02h ; Функция вывода символа на экран

mov dl,13 ; ASCII-символ возврата каретки

int 21h ; Вызов функции возврата каретки

mov dl,10 ; Код символа - переход на новую строку

int 21h ; Вызов функции

; ----------------------------------

; Вывод несовпадающих символов строк

; ----------------------------------

mov dl,[byte ptr si]

int 21h

mov dl,'<'

int 21h

mov dl,'>'

int 21h

mov dl,[byte ptr di]

int 21h

inc si ; Продолжение поиска в строке

inc di ; после обнаружения несовпадения

mov ax,1 ; Фиксирование факта о несовпадении символов

jmp Cycl

mov ah,08h ; Функция ожидания нажатия любой клавиши

int 21h ; Вызов DOS: код нажатой клавиши - в AL

Exit:

mov ax,4C00h

int 21h

END Main

Пример 3. Демонстрация установки пароля в программе для продолжения её работы при верном вводе пароля

STK SEGMENT STACK ; Откроем сегмент стека

DB 256 DUP (?) ; Отводим под стек 256 байтов

STK ENDS ; Закроем сегмент стека

DATA SEGMENT

password DB 'data' ; Ожидаемый пароль

leng=$-password

string DB 80 DUP (?) ; Поле для ввода пароля

prompt DB 'Введите пароль: $' ; Запрос

er DB 0Ah,0Dh,'Неверный пароль! $'

ok DB 0Ah,0Dh,'Доступ к программе открыт!',0Ah,0Dh,'$'

prog DB 'Секретный шифр: 1422-07-02 $'

DATA ENDS

CODE SEGMENT

ASSUME CS:code, DS:data

Begin:

mov ax,data

mov ds,ax

; --------

mov ah,09h

mov dx,OFFSET prompt

int 21h

; -----------

; Ввод пароля

; -----------

sub bx,bx ; (BX)=0

; (BX)=<количество_введенных_символов>

Pass:

mov ah,08h ; Функция ввода символа без отображения

int 21h ; на экране дисплея

cmp al,13 ; Проверка на конец ввода строки

je Compare ; Ввод строки закончен

mov string[bx],al ; Запись введённого символа в память

inc bx ; (BX)=(BX)+1

jmp Pass ; Продолжение ввода пароля

; ------------------------------------------------

; Сравнение строк для проверки правильности пароля

; ------------------------------------------------

Compare:

push ds ; Помещение в стек адреса DS

pop es ; Отображение данных в ES

lea si,string ; (SI)=<Смещение_строки_string>

lea di,password ; (DI)=<Смещение_строки_password>

cld ; Сброс флага направления

cmp bx,leng

jne Error

mov cx,bx ;(CX)=<Количество_введённых_символов>

repe cmpsb ; Посимвольное сравнение

jne Error ; Несовпадение строк

; -------------------------------------------------------

; Вывод сообщения ok, подтверждающего правильность пароля

; -------------------------------------------------------

mov ah,09h

mov dx,OFFSET ok

int 21h

; ------------------------------------

; Программа, к которой появился доступ

; ------------------------------------

mov ah,09h

mov dx,OFFSET prog

int 21h

Exit:

mov ah,08h ; Функция ожидания нажатия любой клавиши

int 21h ; Вызов DOS: код нажатой клавиши - в AL

mov ax,4C00h

int 21h

Error: ; Введён неправильный пароль

mov ah,09h

mov dx,OFFSET er

int 21h

jmp Exit

CODE ENDS

END Begin

Пример 4. Демонстрация использования команды LODS для определения факта, совпадают ли первый и предпоследний символы данной строки

MASM

MODEL small

.STACK 256

.DATA

s1 DB'Первыйипредпоследний символы строки совпадают!','$'

s2 DB 'Первый и предпоследний символы строки ','$'

s3 DB 'не совпадают!','$'

string DB "НЕ ДО ЛОГИКИ - ГОЛОДЕН!",0ah,0dh,'$'

; --------------------------------------------------------

; После просмотра результата программы при исходных данных

; закомментируйте предыдущую строку и уберите знак

; комментария со следующей строки

; ----------------------------------------------

; string DB "Не до логики - голоден!",0ah,0dh,'$'

N=$-string ; Длина строки string

.CODE

ASSUME ds:@data, es:@data;Привязка DS и ES к сегменту данных

Main:

mov ax,@data

mov ds,ax ; Настройка регистров ds и es

mov es,ax ; на адрес сегмента данных

; --------

mov ah,09h

lea dx,string

int 21h ; Вывод строки string

; ------------------

mov si,OFFSET string ; Присвоить si адрес цепочки

lods string ; Получить первый байт цепочки

dec si ; (SI)=<Адрес_первого_байта_строки>

add si,N-5 ; (SI)=<Адрес_предпоследнего_байта_строки>

cmp [si],al

je Yes

mov ah,09h

lea dx,s2

int 21h ; Вывод сообщения s2

lea dx,s3

int 21h ; Вывод сообщения s3

jmp Exit

Yes:

mov ah,09h

lea dx,s1

int 21h ; Вывод сообщения s1

Exit:

mov ah,08h ; Функция ожидания нажатия любой клавиши

int 21h ; Вызов DOS: код нажатой клавиши - в AL

mov ax,4C00h

int 21h

END Main

Пример 5. Программа осуществляет ввод строки с клавиатуры, размещение её в памяти по адресу ES:DI и вывод на экран

; Программа разбита на следующие процедуры:

; WrStr - печать Вашей строки

; WrStr1 - печать prigl1

; WrStr2 - печать prigl2

; RdStr - чтение Вашей строки с клавиатуры

; и запись ее по адресу ES:DI

; Space - переход курсора на начало новой строки

; ----------------------------------------------

IDEAL

MODEL small

STACK 256

DATASEG

exCode DB 0

prigl1 DB "Введите строку из 10 символов.","$"

prigl2 DB "Вот ваша строка: ","$"

UDATASEG

string DB 11 dup (?) ; Резервирование пространства под

; Вашу строку

CODESEG

Start:

mov ax,@data ; Инициализация сегментных регистров

mov ds,ax ; DS

mov es,ax ; ES

call WrStr1 ; Печать приглашения1

call Space

call RdStr ; Размещение вашей строки в памяти

call Space

call WrStr2 ; Печать приглашения2

call Space

call WrStr ; Печать Вашей строки

mov ah,8 ; Функция ожидания нажатия любой клавиши

int 21h ; Вызов DOS: код нажатой клавиши - в AL

Exit:

mov ah,04Ch ; Функция DOS: выход из программы

mov al,[exCode] ; Возврат значения кода ошибки

int 21h ; Вызов DOS. Останов программы

; *********

PROC WrStr2

mov dx,OFFSET prigl2 ; prigl2 по адресу DS:DX

mov ah,09 ; Функция DOS: печать ASCII-строки

int 21h

ret

ENDP WrStr2

; *********

PROC WrStr

mov dx,OFFSET string ; string по адресу DS:DX

mov ah,9 ; Функция DOS: печать ASCII-строки

int 21h

ret

ENDP WrStr

; *********

PROC WrStr1

mov dx,OFFSET prigl1 ; Инициализация смещения prigl1

mov ah,09 ; Функция вывода prigl1

int 21h

ret

ENDP WrStr1

; *********

PROC Space

mov ah,2 ; Функция DOS: печать символа из DL

mov dl,13 ; ASCII-символ возврата каретки

int 21h

mov dl,10 ; ASCII-символ перехода на новую строку

int 21h

ret ; Возврат в основную программу

ENDP Space

; ********

PROC RdStr

mov di,OFFSET string ; Адрес строки ES:DI

mov cx,10 ; Длина строки

mov ah,1 ; Функция DOS: чтение с клавиатуры символа

cmp cx,0

je Zero

cld ; Сброс флага направления

Repeat:

int 21h ; Запись введенного значения в регистр AL

stosb ; Запись символа из AL в ES:DI

loop Repeat ; DI<-DI+1

Zero:

mov al,24h ; Запись последнего символа "$"

stosb ; DI<-DI+1

ret

ENDP RdStr

END Start ; Конец программы / точка входа