7. Обмен данными с программой pSpice

Программа PSpice является наиболее известной реализацией программы схемотехнического моделирования SPICE (Simulation Program with Integrated Circuit Emphasis), разработанной в Калифорнийском университете в начале 70-х годов прошлого столетия и де-факто ставшей эталоном в системах схемотехнического моделирования .

Обмен данными с PSpice и другими программами (OrCAD, EWB Layout и др.) производится с помощью команд Export и Import меню File . Начнем с команды Export. Перед ее выполнением необходимо загрузить файл схемы. В качестве примера выберем схему генератора Колпитца на рис. 1.23 (схемный файл 2m-oscil.ewb). После выбора команды Export вызывается диалоговое окно (рис. 1.39), в котором необходимо в строке "Имя файла:" указать имя файла. По умолчанию предлагается имя схемного файла, однако его рекомендуется изменить. Рекомендуется также поместить этот файл в каталог Models\Subckts.

В строке "Тип файла" можно выбрать следующие типы файлов: SPICE (*.cir), OrCAD PCB (*.net), Tango (*.net), Eagle (*.scr), Layo1 (*.cmp), Ultimate (*.plc), EWB Layout (*.plc).

Рис. 1.39. Диалоговое окно команды Export

При выборе типа файла SPICE получаем файл с расширением .cir (в данном случае 2m-osc.cir) с текстовым описанием схемы в формате PSpice, содержание которого показано нарис. 1.40. Текстовый файл начинается с шапки-заголовка (комментарии — с символа "*"), в котором указывается имя схемного файла EWB и приводятся другие данные.

В абзаце с комментарием Oscilloscope(s) сообщается, что в пакете PSpice для отображения результатов моделирования будет использована команда PROBE, при этом параллельно клеммам осциллографа включается резистор R_o_scope_0_0 сопротивлением 10¹² Ом , а напряжение измеряется между узлами 3 и 0 (0 — узел заземления).

В абзаце Batery(s) приводится описание источника питания V0 напряжением 6 В, включенного между узлами 2 и 0.

В абзаце Resistor(s) перечисляются входящие в схему резисторы R1 (1 кОм) и R0 (10 кОм), включенные между узлами 3, 0 и 1, 2 соответственно.

В абзаце Capacitor(s) перечисляются используемые в схеме конденсаторы С1 (82 пФ) и СО (82 пФ), включенные между узлами 4, 3 и 3, 1 соответственно.

В абзаце NPN Transistor(s) указывается тип транзистора Q0 в формате PSpice (Qn2n_2N2222A), коллектор, база и эмиттер которого подключены к узлам 2, 4 и 3 соответственно.

* c:\program files\ewb512\circuits\2m-oscil.ewb **

* Interactive Image Technologies *

* *

* This File was created by: *

* Electronics Workbench to SPICE netlist *

* conversion DLL *

* *

* Wed Jun 05 20:24:57 2002 *

**************************************************

* Oscilloscope(s)

.PROBE V(3, 0)

R_o_scope_0_0 3 0 1Tohm

.PROBE V(OPEN_1, 0)

R_o_scope_0_1 OPEN_1 0 1Tohm

* Battery(s)

* E

V0 2 0 DC 6

* Resistor(s)

* R1

R0 1 2 10K

* R2

R1 3 0 1K

* Capacitor(s)

* C2

C1 4 3 82p

* C1

C0 3 1 82p

* NPN Transistor(s)

*

Q0 2 4 3 Qn2n_2N2222A

* Inductor(s)

* L

L0 1 4 120u

* Connector(s)

* node = 4, label =

* node = 2, label =

* node = 3, label =

* node = 1, label =

* node = 1, label =

* node = 0, label =

* Misc

.TRAN 5.6ns 2.8us 0s 5.6ns UIC

.MODEL Qn2n_2N2222A NPN(Is=11.6f BF=200 BR=4 Rb=1.69 Re=423m Rc=169m Cjs=0

+Cje=19.5p Cjc=9.63p Vje=750m Vjc=750m Tf=454p Tr=102n mje=333m mjc=333m

+VA=113 ISE=170f IKF=410m Ne=2 NF=1 NR=1 VAR=1e+30 IKR=1e+30 ISC=0 NC=2

+IRB=1e+30 RBM=0 XTF=0 VTF=1e+30 ITF=0 PTF=0 XCJC=1 VJS=750m MJS=0 XTB=0

+EG=1.11 XTI=3 KF=0 AF=1 FC=500m TNOM=27)

.END

Рис. 1.40. Содержание файла 2m-oscil.cir — задания на моделирование для программы PSpice

В абзаце Inductor(s) указывается на подключение между узлами 1 и 4 катушки L0 индуктивностью 120 мкГн (в EWB используется символ "u" вместо " ").

В абзаце Connector(s) приводятся имена меток, если таковые имеются, и необходимые при этом комментарии.

В разделе Misc приводятся параметры директивы расчета переходных процессов. TRAN: шаг вывода данных (28 нс), конечное время (14 мкс), начальный момент времени вывода данных (0 с), максимальный шаг вывода данных (28 нс), отмена расчета режима по постоянному току перед расчетом переходных процессов (UIC). Директивой .MODEL задаются параметры используемого в схеме транзистора . Директивой .OPTIONS задаются параметры моделирования (см. разд. 1.6).

Файл заканчивается директивой .END (конец описания).

 

Следует заметить, что рассмотренную команду можно использовать и для одиночных компонентов, например, для определения их эквивалентных схем (пример такого применения приведен в гл. 4). Для этого необходимо из каталога соответствующей библиотеки скопировать (перенести) на рабочее поле программы графическое изображение компонента и выполнить команду File>Export. Теперь рассмотрим обратную задачу — импорт файлов в формате PSpice, при котором в программе EWB выполняется построение принципиальной схемы. После выбора команды Import открывается диалоговое окно (рис. 1.41), в котором указывается имя импортируемого файла (только в формате SPICE). После этого вызывается меню размещения (Part Placement на рис. 1.42, а). Выбор в этом меню режимов Default (по умолчанию) и Quick (быстрый) приводит к достаточно быстрому выводу схемы, однако она получается крайне неудобочитаемой. Выбор режима Customized (самостоятельная настройка) приводит к цепочке последовательно вызываемых меню, показанных на рис. 1.42—1.44.

Рис. 1.41. Диалоговое окно команды Import

В режиме Rod Nodes (меню на рис. 1.42, б) в начале процесса формирования изображения схемы выбираются два узла с наибольшим числом подключенных к ним компонентов, остальные элементы схемы располагаются справа и слева от выбранных узлов. В режиме Point Nodes в качестве опорных используются узлы схемы. В режиме Place All (используется по умолчанию при выборе режима Default в меню на рис. 1.42, а) сначала размещаются компоненты схемы, а затем производится их соединение и оптимизация размещения всей схемы.

а	б

Рис. 1.42. Меню выбора параметров вывода графического изображения схемы на первом (а) и втором (б) этапах

а	б

Рис. 1.43. Меню выбора параметров вывода графического изображения схемы на третьем (а) и четвертом (б) этапах

Рис. 1.44. Меню выбора максимального количества соединений в одной точке

При режимах, указанных в меню на рис. 1.42—1.44, схема генератора Колпитца после ее импортирования имеет весьма непредсказуемый вид. Она отличается от исходной схемы на рис. 1.23 несколько иным и менее удачным расположением компонентов и наличием сопротивления утечки (входным сопротивлением) осциллографа R_o_scope_0_0.

При импортировании схем, подготовленных в текстовом виде для программы PSpice, необходимо предварительно загрузить в каталог Models необходимые библиотечные файлы (с расширением .lib) и перезагрузить EWB. Если необходимые для импортируемой схемы данные находятся в файлах с расширением .mod (файлы моделей компонентов) и .net (список соединений схемы), то, согласно руководству пользователя [67], их необходимо соответственно изменить на .lib и .cir и также загрузить в указанный каталог.

Контрольные вопросы и задания #1 [ Часть 1 ] [ Часть 2 ] [ Часть 3 ] [ Часть 4 ]

 

Контрольные вопросы и задания #4

[ Часть 1 ] [ Часть 2 ] [ Часть 3 ] [ Часть 4 ]