9.3.10. Список

Свойство

Описание

Align

Способ выравнивания компонента в пределах содержащего компонента.

AutoComplete

Если равно True, то можно быстро выбрать элемент, если начать набирать его текст на клавиатуре.

BevelEdges

Вложенные свойства beLeft, beTop, beRight и beBottom определяют видимость соответственно левой, верхней, правой и нижней сторон рельефной рамки.

BevelInner

Внутренний скос рельефной рамки: bvNone — скос отсутствует, bvLowered — скос внутрь, bvRaised — скос наружу; bvSpace — скос заменяется отступом.

BevelKind

Вид рельефной рамки: bkNone — рамки нет, bkTile — рамка с четкими скосами, bkSoft — рамка со сглаженными скосами, bkFlat — плоская рамка (без скосов).

BevelOuter

Внешний скос рельефной рамки: bvNone — скос отсутствует, bvLowered — скос внутрь, bvRaised — скос наружу; bvSpace — скос заменяется отступом.

BorderStyle

Определяет, имеет ли список рамку.

Columns

Количество колонок в списке.

ExtendedSelect

Если равно значению True, то пользователь может выбрать в списке диапазон элементов (однако лишь в том случае, если MultiSelect тоже равно значению True).

IntegralHeight

Если равно значению True, то высота списка автоматически уменьшается, чтобы быть кратной высоте элемента.

ItemHeight

Высота элемента списка, когда значение свойства Style равно lbOwnerDrawFixed.

Items

Элементы списка.

MultiSelect

Если равно значению True, то пользователь может выбрать в списке несколько элементов.

ScrollWidth

Логическая ширина списка в пикселях. Если значение свойства ScrollWidth больше значения свойства Width, то появляется горизонтальная полоса прокрутки. В противном случае полоса прокрутки не показывается.

Sorted

Если равно значению True, то элементы списка сортируются в алфавитном порядке.

Style

Стиль отображения списка (см. табл. 9.15).

OnData

Предназначено для формирования списка элементов перед рисованием. Происходит только в том случае, если свойство Style содержит значение lbVirtual или lbVirtualOwnerDraw.

OnDataFind

Происходит, когда пользователь пытается быстро перейти к элементу, набирая текст элемента на клавиатуре. Обработчик этого события должен на основании введенной пользователем строки вернуть номер соответствующего элемента. Возникает только в том случае, если свойство Style содержит значение lbVirtual или lbVirtualOwnerDraw.

OnDataObject

Происходит при обращении к массиву Objects в списке Items, но только в том случае, если свойство Style содержит значение lbVirtual или lbVirtualOwnerDraw. Обработчик события должен вернуть соответствующий элементу объект.

OnDrawItem

Происходит при рисовании отдельно взятого элемента списка, но только в том случае, если свойство Style содержит одно из следующих значений: lbOwnerDrawFixed, lbOwnerDrawVariable, lbVirtualOwnerDraw.

OnMeasureItem

По замыслу разработчиков событие происходит при расчете высоты отдельно взятого элемента списка перед его рисованием на экране и лишь в том случае, если свойство Style содержит значение lbOwnerDrawVariable. Однако из-за дефекта в модуле StdCtrls событие OnMeasureItem не срабатывает.

Значение

Описание

LbStandard

Все элементы списка имеют одинаковую высоту, которая рассчитывается исходя из размера шрифта.

LbOwnerDrawFixed

Все элементы списка имеют одинаковую высоту, заданную в свойстве ItemHeight. За рисование элементов отвечает программист, который должен создать обработчик события OnDrawItem.

lbOwnerDrawVariable

По замыслу разработчиков элементы списка имеют разную высоту, определяемую в обработчике события OnMeasureItem (из-за дефекта в модуле StdCtrls событие не срабатывает). За рисование элементов отвечает программист, который должен создать обработчик события OnDrawItem.

LbVirtual

Элементы списка хранятся отдельно от компонента и запрашиваются с помощью события OnData. За рисование элементов отвечает компонент.

LbVirtualOwnerDraw

Элементы списка хранятся отдельно от компонента и запрашиваются с помощью события OnData. За рисование элементов отвечает программист, который должен создать обработчик события OnDrawItem.

procedure TMainForm.NewButtonClick(Sender: TObject);

var

Alarm: TAlarm;

begin

AlarmDetailsForm := TAlarmDetailsForm.Create(Self);

try

// Выполнить диалог

if AlarmDetailsForm.ShowModal = mrOK then

begin

// Создать новый объект будильника

Alarm := TAlarm.Create;

// Получить параметры будильника из диалога

AlarmDetailsForm.GetData(Alarm);

// Добавить будильник в список и выбрать его

AlarmListBox.ItemIndex := AlarmListBox.Items.AddObject(

Alarm.GetAlarmStr, Alarm);

end;

finally

AlarmDetailsForm.Free;

end;

end;

procedure TMainForm.FormDestroy(Sender: TObject);

var

I: Integer;

begin

for I := 0 to AlarmListBox.Items.Count - 1 do

AlarmListBox.Items.Objects[I].Free;

end;

procedure TMainForm.EditButtonClick(Sender: TObject);

var

Alarm: TAlarm;

SavedIndex: Integer;

begin

AlarmDetailsForm := TAlarmDetailsForm.Create(Self);

try

// Получить выбранный будильник

with AlarmListBox do Alarm := TAlarm(Items.Objects[ItemIndex]);

// Установить управляющие элементы диалога в соответствии с

// параметрами будильника

AlarmDetailsForm.SetData(Alarm);

// Выполнить диалог

if AlarmDetailsForm.ShowModal = mrOK then

begin

// Получить из диалога новые параметры будильника

AlarmDetailsForm.GetData(Alarm);

with AlarmListBox do

begin

// Запомнить номер выбранного в списке элемента

SavedIndex := ItemIndex;

// Изменить текст элемента

// При этом элемент перестает быть выбранным

Items.Strings[ItemIndex] := Alarm.GetAlarmStr;

// Восстановить номер выбранного в списке элемента

ItemIndex := SavedIndex;

end;

end;

finally

AlarmDetailsForm.Free;

end;

end;

procedure TMainForm.DeleteButtonClick(Sender: TObject);

begin

with AlarmListBox do

begin

// Разрушить объект будильника

Items.Objects[ItemIndex].Free;

// Удалить из списка соответствующую объекту строку

Items.Delete(ItemIndex);

end;

end;

procedure TMainForm.ApplicationEventsIdle(Sender: TObject;

var Done: Boolean);

begin

EditButton.Enabled := AlarmListBox.ItemIndex <> -1;

DeleteButton.Enabled := AlarmListBox.ItemIndex <> -1;

Done := True; // предотвращает непрерывную генерацию события OnIdle

end;