Поддержка истинности

Если некоторый факт вводится в список фактов в результате выполнения команды assert, записанной в правой части правила, то можно считать такой факт следствием тех фактов, которые привели к срабатыванию этого правила (т. е. тех которые соответствовали образам из левой части правила). Если затем один из таких фактов будет удален из списка фактов то, можно было бы ожидать, что также будут удалены и все его следствия. Однако по умолчанию этого не произойдет. Такое поведение объясняется тем, что система CLIPS по умолчанию не запоминает причинно-следственные связи между фактами.

Чтобы изменить такое поведение надо использовать в левой части правила условие logical. В этом случае все факты, добавляемые в список фактов в правой части правила, будут иметь т. н. логическую поддержку в виде фактов соответствующих образцам, указанным в пределах условия logical. Один и тот же факт может иметь несколько логических поддержек в том случае, если он был добавлен в список фактов несколькими разными активациями (разумеется, фактически добавление произойдет только в результате срабатывания первой активации, остальные же активации лишь будут добавлять дополнительные поддержки).

Когда из списка фактов удаляется факт, входящий в какие-либо логические поддержки, то вместе с ним удаляются и эти поддержки. Это в свою очередь приводит к автоматическому удалению всех фактов, оставшихся без логических поддержек.

Отметим, что если факт добавляет в список фактов командой reset или командой assert, находящейся либо вне правой части правила, либо в правой части правила, не имеющего условия logical, то такой факт получает т. н. безусловную поддержку.

Пример:

CLIPS> (defrule rule-1

(logical (weather-forecast rain))

=>

(assert (need-to-take umbrella)))

CLIPS> (defrule rule-2

(logical (sky overcast))

=>

(assert (need-to-take umbrella)))

CLIPS> (assert (weather-forecast rain))

<Fact-1>

CLIPS> (assert (sky overcast))

<Fact-2>

CLIPS> (run)

CLIPS> (facts)

f-0 (initial-fact)

f-1 (weather-forecast rain)

f-2 (sky overcast)

f-3 (need-to-take umbrella)

For a total of 4 facts.

CLIPS> (retract 1)

CLIPS> (facts)

f-0 (initial-fact)

f-2 (sky overcast)

f-3 (need-to-take umbrella)

For a total of 3 facts.

CLIPS> (retract 2)

CLIPS> (facts)

f-0 (initial-fact)

For a total of 1 fact.

Стратегии

В системе CLIPS поддерживаются следующие стратегии:

• depth

• breadth

• simplicity

• complexity

• lex — похожа на depth, но отмечает каждый факт временной меткой и отдает предпочтение активации с более поздними метками. Если активация зависит от нескольких фактов, то их метки упорядочиваются;

• mea — предпочтение отдается активации, для который первый факт имеет позднейшую временную метку. Если же первый факты имеют одинаковую метку, то как lex;

• random — в случайном порядке.

Последовательности

Помимо типов данных, представляющих единичные значения, такие символы, строки или числа, система CLIPS поддерживает тип данных, представляющий последовательность значений. Для обозначения этого типа данных в системе CLIPS используется термин мультиполе (multifield). Элементами последовательности могут быть единичные значения любого типа; однако элемент последовательность сам не может быть последовательностью, т. е, вложенные последовательности не допускаются. Количество элементов в последовательности называется длиной. Последовательность может вовсе не содержать элементов, в этом случае она называется пустой; длина пустой последовательности равна 0. Отметим также, что система CLIPS различает единичные значения и последовательности, состоящие из одного элемента.

Для создания новой последовательности можно использовать функцию create$; элементы возвращаемой последовательности перечисляются при вызове функции в качестве параметров. Пример:

CLIPS> (create$ a b 1 2 3)

(a b 1 2 3)

CLIPS> (create$)

()

CLIPS> (create$ a b (create$ 1 2) 3)

(a b 1 2 3)

CLIPS> (create$ a)

(a)

Для работы с последовательностью можно использовать следующие функции:

• length$ — возвращает длину последовательности; последовательность задается параметром;

• nth$ — возвращает элемент последовательности по номеру; номер задается первым параметром, а последовательность — вторым. Нумерация элементов начинается с 1. Если элемента с заданным номером нет, то функция возвращает символ nil;

• subseq$ — возвращает часть последовательности по диапазону номеров; последовательность задается первым параметром, а номера первого и последнего элементов — вторым и третьим. Если одного или обоих граничных элементов в последовательности нет, то возвращаются только те элементы, которые есть (т. е. ошибки не возникает);

• member$ — ищет в последовательности элемент с указанным значением и возвращает номер первого найденного элемента; искомое значение задается первым параметром, а сама последовательность — вторым. Если искомого значения в последовательности нет, то функция возвращает символ FALSE. Если искомое значение само является последовательностью, то в случае успеха функция возвращает последовательность из двух элементов, задающих границы части последовательности, совпадающей искомой.

Примеры:

CLIPS> (bind ?s (create$ a b 1 2 1))

(a b 1 2 1)

CLIPS> (length$ ?s)

5

CLIPS> (nth$ 2 ?s)

b

CLIPS> (nth$ 6 ?s)

nil

CLIPS> (subseq$ ?s 2 4)

(b 1 2)

CLIPS> (subseq$ ?s 2 8)

(b 1 2 1)

CLIPS> (subseq$ ?s 6 8)

()

CLIPS> (member$ b ?s)

2

CLIPS> (member$ 1 ?s)

3

CLIPS> (member$ c ?s)

FALSE

CLIPS> (member$ (create$ b 1) ?s)

(2 3)

CLIPS> (member$ (create$ b 2) ?s)

FALSE

Вставка и удаление элементов последовательности в системе CLIPS также реализована функциями. Однако эти функции не изменяют оригинальную последовательность — вместо этого они возвращают новую последовательность, созданную на основе исходной. Перечислим эти функции, заметив, что исходная последовательность во всех них задается первым параметром:

• insert$ — вставляет в последовательность новые элементы начиная с указанного номера; номер задается вторым параметром, а значения новых элементов — параметрами начиная с третьего (т. е. первый из вставляемых элементов соответствуют третьему параметры, второй — четвертому, третий — пятому и т. д.);

• delete$ — удаляет часть последовательности по диапазону номеров; диапазон номеров задается вторым и третьим параметрами. При попытке удалить несуществующие элементы возникает ошибка;

• delete-member$ — удаляет из последовательности элементы по значению; значения удаляемых элементов задаются параметрами начиная со второго. Если некоторое удаляемое значение совпадает с несколькими элементами исходной последовательности, то функция удаляются все такие элементы. Если ни один элемент исходной последовательности не совпадает ни одним из удаляемых значений, то функция возвращает исходную последовательность без изменений. Порядок перечисления удаляемых значений не важен;

• replace$ — заменяет часть последовательности, заданной диапазоном номеров, новыми элементами; диапазон номеров задается вторым и третьим параметрами, а значения новых элементов — параметрами начиная с четвертого;

• replace-member$ — заменяет элементы последовательности, заданные значениями, новыми значением или последовательностью; новое значение или последовательность задается вторым параметром, а значения удаляемых элементов — параметрами, начиная с третьего.

• subsetp

CLIPS> (bind ?s (create$ a b 1))

(a b 1)

CLIPS> (insert$ ?s 3 a 2)

(a b a 2 1)

CLIPS> ?s

(a b 1)

CLIPS> (bind ?s (insert$ ?s 3 a 2))

(a b a 2 1)

CLIPS> ?s

(a b a 2 1)

CLIPS> (insert$ ?s 4 x (create$ y z))

(a b a x y z 2 1)

CLIPS> (delete$ ?s 2 3)

(a 2 1)

CLIPS> (delete-member$ ?s b)

(a a 2 1)

CLIPS> (delete-member$ ?s a b)

(2 1)

CLIPS> (delete-member$ ?s c)

(a b a 2 1)

CLIPS> (replace$ ?s 2 3 x)

(a x 2 1)

CLIPS> (replace$ ?s 2 3 x y z)

(a x y z 2 1)

CLIPS> (replace-member$ ?s x a)

(x b x 2 1)

CLIPS> (replace-member$ ?s x a b)

(x x x 2 1)

CLIPS> (replace-member$ ?s (create$ x y) a)

(x y b x y 2 1)

Последовательности могут использоваться для представления множеств (за неимением в системе CLIPS более подходящего типа данных). Чтобы проверить является ли одно множество, заданное последовательность, подмножеством другого множества, также заданного списком, можно использовать функцию subsetp. Эта функция возвращает символ TRUE, если первый аргумент является подмножеством второго, или символ FALSE в противном случае. Повторяющиеся элементы в каждой из последовательностей не учитываются; порядок элементов не важен. Пример:

CLIPS> (subsetp (create$ a b) (create$ b c a))

TRUE

CLIPS> (subsetp (create$ a b) (create$ b a))

TRUE

CLIPS> (subsetp (create$ a b) (create$ b c))

FALSE

Одна последовательность может использоваться для задания сразу же нескольких аргументов функции; для этого используется функция expand$, параметром которой является раскрываемая последовательность. Вызов функции expand$ может размещаться только в пределах вызова какой-либо другой функции. Пример:

CLIPS> (bind ?t (create$ 1 2 3))

(1 2 3)

CLIPS> (+ (expand$ ?t))

6

CLIPS> (+ 10 (expand$ ?t))

16

Отметим, что не все функции допускают использование expand$.

Последовательность могут использоваться в команде assert для задания параметров фактов. При этом такие последовательности раскрываются автоматически (без использования функции expand$). Пример:

CLIPS> (assert (seq a b c))

<Fact-1>

CLIPS> (assert (seq (create$ b c) d))

<Fact-2>

CLIPS> (facts 1)

f-1 (seq a b c)

f-2 (seq b c d)

For a total of 2 facts.

При сопоставлении с образцом, переменной, входящей в образец может быть присвоено не только значение одного параметра факта, сопоставленного образцу, но и последовательность значений параметров. Для этого перед именем переменной записывается знак доллара. Пример:

CLIPS> (assert (num-seq 1 2 3 4))

<Fact-1>

CLIPS> (assert (num-seq 20 30 40))

<Fact-2>

CLIPS> (defrule print-all-sum

(num-seq $?n)

=>

(printout t (+ (expand$ ?n)) crlf))

CLIPS> (run)

90

10

CLIPS> (defrule print-all-but-first-sum

(num-seq ? $?n)

=>

(printout t (+ (expand$ ?n)) crlf))

CLIPS> (run)

70

9

CLIPS> (defrule print-all-but-last-sum

(num-seq $?n ?)

=>

(printout t (+ (expand$ ?n)) crlf))

CLIPS> (run)

6

50

Напомним, что если значение, присваиваемое переменной в ходе сопоставления факта образцу не важно, то вместо переменной можно использовать заполнитель. Пример:

CLIPS> (defrule print-last

(num-seq $? ?n)

=>

(printout t ?n crlf))

CLIPS> (run)

40

4

В том случае, когда в один образец входят несколько переменных, которым присваиваются последовательности, система CLIPS порождает отдельную активацию для каждого возможного распределения параметров между этими переменным, что в частности приводит к тому, что один факт и тот же может породить несколько активаций одного и того же правила. Пример:

CLIPS> (defrule print-two-sums

(num-seq $?n1 $?n2)

=>

(printout t (+ 0 0 (expand$ ?n1)) " " (+ 0 0 (expand$ ?n2)) crlf))

CLIPS> (agenda)

0 print-two-sums: f-2

0 print-two-sums: f-2

0 print-two-sums: f-2

0 print-two-sums: f-2

0 print-two-sums: f-1

0 print-two-sums: f-1

0 print-two-sums: f-1

0 print-two-sums: f-1

0 print-two-sums: f-1

For a total of 9 activations.

CLIPS> (run)

0 90

20 70

50 40

90 0

0 10

1 9

3 7

6 4

10 0

Присваивание последовательностей нескольким переменным в одном образце представляет собой мощное средство которым, однако, следует пользоваться с осторожностью, чтобы не вызвать появления чрезмерного количества активаций.